2.2. Wat is het aantal cliënten per wet?

Concepten

• Forensische indicatiestelling
• Indicatiebesluit
• Mens
• Vestiging
• Vestigingsnummer
• Wlz-indicatie
• Wmo-indicatie
• Zvw-indicatie

Relaties

• deel van
• gaat over
• gedefinieerd door
• geïdentificeerd door
• heeft perdurantlocatie

Eigenschappen

• einddatum
• heeft datawaarde
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: RIVM 2.2
2# Parameters: ?peildatum
3# Ontologie: versie 3.0.0 of nieuwer
4
5PREFIX onz-g: <http://purl.org/ozo/onz-g#>
6PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
7PREFIX onz-org: <http://purl.org/ozo/onz-org#>
8PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
9PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
10PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
11
12SELECT 
13    (?vestiging AS ?Indeling)
14    (COUNT(DISTINCT IF(BOUND(?wlz), ?client, ?unbound)) AS ?Aantal_Wlz)
15    (COUNT(DISTINCT IF(BOUND(?zvw), ?client, ?unbound)) AS ?Aantal_Zvw)
16    (COUNT(DISTINCT IF(BOUND(?wmo) || BOUND(?forensisch), ?client, ?unbound)) AS ?Aantal_overig)
17WHERE {
18    {
19        # Per vestiging
20        SELECT ?client ?wlz ?zvw ?wmo ?forensisch ?vestiging
21        WHERE {
22            # peildatum: maandag van de week
23            # BIND("2024-01-01"^^xsd:date AS ?peildatum)
24
25            BIND(?peildatum AS ?startperiode)
26            BIND(?startperiode + "P6D"^^xsd:duration AS ?eindperiode)
27
28            { 
29                ?indicatie a onz-zorg:IndicatieBesluit 
30            } UNION {
31                ?indicatie a onz-zorg:ForensischeIndicatieStelling
32            }
33
34            ?indicatie
35                onz-g:isAbout ?client ;
36                onz-g:startDatum ?start_indicatie .
37
38            OPTIONAL { ?indicatie onz-g:eindDatum ?eind_indicatie . }
39
40            FILTER (
41                ?start_indicatie <= ?eindperiode &&
42                (!BOUND(?eind_indicatie) || ?eind_indicatie >= ?startperiode)
43            )
44
45            ?client a onz-g:Human .   
46
47            OPTIONAL {
48                ?indicatie a onz-zorg:WlzIndicatie .
49                BIND(1 AS ?wlz)
50            }
51            OPTIONAL {
52                ?indicatie a onz-zorg:ZvwIndicatie .
53                BIND(1 AS ?zvw)
54            }
55            OPTIONAL {
56                ?indicatie a onz-zorg:WmoIndicatie .
57                BIND(1 AS ?wmo)
58            }
59            OPTIONAL {
60                ?indicatie a onz-zorg:ForensischeIndicatieStelling .
61                BIND(1 AS ?forensisch)
62            }
63
64            ?zorgproces
65                onz-g:definedBy ?indicatie ;
66                onz-g:hasPerdurantLocation ?locatie .
67
68            OPTIONAL { ?zorgproces onz-g:eindDatum ?eind_zorgproces . }
69
70            FILTER (
71                !BOUND(?eind_zorgproces) ||
72                ?eind_zorgproces >= ?startperiode
73            )
74
75            ?locatie onz-g:partOf* ?vestiging_uri .
76            ?vestiging_uri a onz-org:Vestiging ;
77                onz-g:identifiedBy ?vest_nr . 
78            ?vest_nr a onz-org:Vestigingsnummer ;
79                onz-g:hasDataValue ?vestiging .
80        }
81    }
82    UNION
83    {
84        # Totaal organisatie
85        SELECT ?client ?wlz ?zvw ?wmo ?forensisch ("Totaal organisatie" AS ?vestiging)
86        WHERE {
87            # BIND("2024-01-01"^^xsd:date AS ?peildatum)
88
89            BIND(?peildatum AS ?startperiode)
90            BIND(?startperiode + "P6D"^^xsd:duration AS ?eindperiode)
91
92            { 
93                ?indicatie a onz-zorg:IndicatieBesluit 
94            } UNION {
95                ?indicatie a onz-zorg:ForensischeIndicatieStelling
96            }
97
98            ?indicatie
99                onz-g:isAbout ?client ;
100                onz-g:startDatum ?start_indicatie .
101
102            OPTIONAL { ?indicatie onz-g:eindDatum ?eind_indicatie . }
103
104            FILTER (
105                ?start_indicatie <= ?eindperiode &&
106                (!BOUND(?eind_indicatie) || ?eind_indicatie >= ?startperiode)
107            )
108
109            ?client a onz-g:Human .   
110
111            OPTIONAL {
112                ?indicatie a onz-zorg:WlzIndicatie .
113                BIND(1 AS ?wlz)
114            }
115            OPTIONAL {
116                ?indicatie a onz-zorg:ZvwIndicatie .
117                BIND(1 AS ?zvw)
118            }
119            OPTIONAL {
120                ?indicatie a onz-zorg:WmoIndicatie .
121                BIND(1 AS ?wmo)
122            }
123            OPTIONAL {
124                ?indicatie a onz-zorg:ForensischeIndicatieStelling .
125                BIND(1 AS ?forensisch)
126            }
127
128            ?zorgproces
129                onz-g:definedBy ?indicatie ;
130                onz-g:hasPerdurantLocation ?locatie .
131
132            OPTIONAL { ?zorgproces onz-g:eindDatum ?eind_zorgproces . }
133
134            FILTER (
135                !BOUND(?eind_zorgproces) ||
136                ?eind_zorgproces >= ?startperiode
137            )
138        }
139    }
140}
141GROUP BY ?vestiging
142ORDER BY ?vestiging