10.1 Wat is het percentage eenpersoonskamers?

Concepten

• Capaciteitswaarde
• Kwaliteit
• Mens
• Onverplaatsbaar artefact
• Vestiging
• Vestigingsnummer
• Wooneenheid

Relaties

• deel van
• deel van
• geïdentificeerd door
• heeft capaciteitsobject
• heeft eigenschap of kenmerk
• heeft eigenschapswaarde

Eigenschappen

• heeft datawaarde

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: RIVM Infectieziektenbestrijding 10.1
2# Canonical id: MONO-0008 - "Wat is het percentage eenpersoonskamers?"
3# Parameters:
4# Ontologie: versie 3.0.0 of nieuwer
5
6PREFIX onz-g: <http://purl.org/ozo/onz-g#>
7PREFIX onz-org: <http://purl.org/ozo/onz-org#>
8PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
9
10SELECT
11(?vestiging AS ?Indeling)
12(COUNT(?wooneenheid) AS ?Aantal_wooneenheden)
13(SUM(IF(?unitCapacity = 1, 1, 0)) AS ?Aantal_éénpersoons_wooneenheden)
14(ROUND(SUM(IF(?unitCapacity = 1, 1, 0)) * 10000 / COUNT(?wooneenheid)) / 100 AS ?Procent_éénpersoons_wooneenheden)
15WHERE {
16    {
17        SELECT ?vestiging ?wooneenheid (MAX(?waarde) AS ?unitCapacity)
18        WHERE {
19            ?wooneenheid
20            a onz-org:WoonEenheid ;
21            onz-g:hasQuality ?cap .
22
23            ?cap
24            a onz-g:Quality ;
25            onz-g:hasQualityValue ?cap_waarde .
26
27            ?cap_waarde a onz-g:CapacityValue ;
28            onz-g:hasDataValue ?waarde ;
29            onz-g:hasCapacityObject onz-g:Human .
30
31            {
32                # Per vestiging
33                ?wooneenheid onz-g:partOf ?locatie .
34                ?locatie
35                a onz-g:StationaryArtifact ;
36                onz-g:partOf* ?vestiging_uri .
37
38                ?vestiging_uri a onz-org:Vestiging ;
39                onz-g:identifiedBy ?vest_nr .
40
41                ?vest_nr a onz-org:Vestigingsnummer ;
42                onz-g:hasDataValue ?vestiging .
43            }
44            UNION
45            {
46                # Totaal organisatie
47                BIND("Totaal organisatie" AS ?vestiging)
48            }
49        }
50        GROUP BY ?vestiging ?wooneenheid
51    }
52}
53GROUP BY ?vestiging
54ORDER BY ?vestiging
55