9.1 Wat is het totaal aantal overleden cliënten per Wlz indicatie?

Concepten

• Forensische indicatiestelling
• Mens
• Vestiging
• Vestigingsnummer
• Wlz-indicatie
• Wmo-indicatie
• ZorgEnVerpleegProces
• Zvw-indicatie

Relaties

• deel van
• gedefinieerd door
• geïdentificeerd door
• heeft deelnemer
• heeft perdurantlocatie

Eigenschappen

• einddatum
• heeft datawaarde
• heeft sterfdatum
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: RIVM Infectieziektenbestrijding 9.1
2# Canonical id: MONO-0011 - "Wat is het totaal aantal overleden cliënten per Wlz indicatie?"
3# Parameters: ?peildatum
4# Ontologie: versie 3.0.0 of nieuwer
5
6PREFIX onz-g: <http://purl.org/ozo/onz-g#>
7PREFIX onz-org: <http://purl.org/ozo/onz-org#>
8PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
9PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
10PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
11PREFIX owl: <http://www.w3.org/2002/07/owl#>
12
13SELECT
14?Indeling
15(COUNT(DISTINCT ?client) AS ?Aantal_overleden_cliënten)
16(COUNT(DISTINCT ?wlzClient) AS ?Aantal_overleden_Wlz)
17(COUNT(DISTINCT ?zvwClient) AS ?Aantal_overleden_Zvw)
18(COUNT(DISTINCT ?overigClient) AS ?Aantal_overleden_overig)
19WHERE {
20    {
21        # Per vestiging
22        # Bereken vestigingen en Totaal apart zodat query werkend is in zowel GraphDB als Fuseki
23        SELECT ?client ?wlzClient ?zvwClient ?overigClient ?Indeling
24        WHERE {
25            # BIND("2009-04-27"^^xsd:date AS ?peildatum)
26
27            BIND(?peildatum AS ?startperiode)
28            BIND(?startperiode + "P6D"^^xsd:dayTimeDuration AS ?eindperiode)
29
30            # Stap 1: Selecteer clienten met sterfdatum binnen de meetperiode
31            ?client a onz-g:Human ;
32            onz-g:hasDateOfDeath ?sterfdatum .
33
34            FILTER(?sterfdatum >= ?startperiode && ?sterfdatum <= ?eindperiode)
35
36            # Stap 2: Bepaal vestiging via het zorg- en verpleegproces
37            ?zorgproces a onz-g:CureAndCareProcess ;
38            onz-g:hasParticipant ?client ;
39            onz-g:definedBy ?indicatie ;
40            onz-g:hasPerdurantLocation ?locatie .
41
42            ?indicatie a ?soortIndicatie ;
43            onz-g:startDatum ?indicatieStart .
44
45            OPTIONAL { ?indicatie onz-g:eindDatum ?indicatieEind . }
46
47            FILTER(
48            ?indicatieStart <= ?sterfdatum &&
49            (!BOUND(?indicatieEind) || ?indicatieEind >= ?sterfdatum)
50            )
51
52            VALUES ?soortIndicatie {
53                onz-zorg:WlzIndicatie
54                onz-zorg:ZvwIndicatie
55                onz-zorg:ForensischeIndicatieStelling
56                onz-zorg:WmoIndicatie
57            }
58
59            BIND(IF(?soortIndicatie = onz-zorg:WlzIndicatie, ?client, 1/0) AS ?wlzClient)
60            BIND(IF(?soortIndicatie = onz-zorg:ZvwIndicatie, ?client, 1/0) AS ?zvwClient)
61            BIND(IF(?soortIndicatie IN (
62            onz-zorg:ForensischeIndicatieStelling,
63            onz-zorg:WmoIndicatie
64            ), ?client, 1/0) AS ?overigClient)
65
66            ?locatie onz-g:partOf* ?vestiging_uri .
67            ?vestiging_uri a onz-org:Vestiging ;
68            onz-g:identifiedBy ?vest_nr .
69            ?vest_nr a onz-org:Vestigingsnummer ;
70            onz-g:hasDataValue ?Indeling .
71        }
72    }
73    UNION
74    {
75        # Totaal organisatie
76        # Wordt onafhankelijk berekend omdat het anders niet werkte in Fuseki
77        SELECT ?client ?wlzClient ?zvwClient ?overigClient ?Indeling
78        WHERE {
79            # BIND("2009-04-27"^^xsd:date AS ?peildatum)
80
81            BIND("Totaal organisatie" AS ?Indeling)
82            BIND(?peildatum AS ?startperiode)
83            BIND(?startperiode + "P6D"^^xsd:dayTimeDuration AS ?eindperiode)
84
85            ?client a onz-g:Human ;
86            onz-g:hasDateOfDeath ?sterfdatum .
87
88            FILTER(?sterfdatum >= ?startperiode && ?sterfdatum <= ?eindperiode)
89
90            ?zorgproces a onz-g:CureAndCareProcess ;
91            onz-g:hasParticipant ?client ;
92            onz-g:definedBy ?indicatie ;
93            onz-g:hasPerdurantLocation ?locatie .
94
95            ?indicatie a ?soortIndicatie ;
96            onz-g:startDatum ?indicatieStart .
97
98            OPTIONAL { ?indicatie onz-g:eindDatum ?indicatieEind . }
99
100            FILTER(
101            ?indicatieStart <= ?sterfdatum &&
102            (!BOUND(?indicatieEind) || ?indicatieEind >= ?sterfdatum)
103            )
104
105            VALUES ?soortIndicatie {
106                onz-zorg:WlzIndicatie
107                onz-zorg:ZvwIndicatie
108                onz-zorg:ForensischeIndicatieStelling
109                onz-zorg:WmoIndicatie
110            }
111
112            BIND(IF(?soortIndicatie = onz-zorg:WlzIndicatie, ?client, 1/0) AS ?wlzClient)
113            BIND(IF(?soortIndicatie = onz-zorg:ZvwIndicatie, ?client, 1/0) AS ?zvwClient)
114            BIND(IF(?soortIndicatie IN (
115            onz-zorg:ForensischeIndicatieStelling,
116            onz-zorg:WmoIndicatie
117            ), ?client, 1/0) AS ?overigClient)
118        }
119    }
120}
121GROUP BY ?Indeling
122ORDER BY ?Indeling
123