1.1.1. Wat is het aantal cliënten per wet?

Concepten

• ForensischeIndicatieStelling
• IndicatieBesluit
• Mens
• Vestiging
• Vestigingsnummer
• ZorgEnVerpleegProces

Relaties

• deel van
• gaat over
• gedefinieerd door
• geïdentificeerd door
• heeft perdurantlocatie

Eigenschappen

• einddatum
• heeft datawaarde
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: IGJ 1.1.1
2# Parameters: ?vestigingsnummer, ?peildatum
3# Ontologie: versie 3.0.0
4
5PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
6PREFIX onz-org: <http://purl.org/ozo/onz-org#>
7PREFIX onz-g: <http://purl.org/ozo/onz-g#>
8PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
9PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
10
11SELECT
12    (COUNT(DISTINCT ?client) AS ?Totaal_aantal_unieke_clienten)
13    (COUNT(DISTINCT IF(BOUND(?zvw), ?client, ?unbound)) AS ?Aantal_clienten_Zvw)
14    (COUNT(DISTINCT IF(BOUND(?wlz), ?client, ?unbound)) AS ?Aantal_clienten_Wlz)
15    (COUNT(DISTINCT IF(!BOUND(?zvw) && !BOUND(?wlz), ?client, ?unbound)) AS ?Aantal_clienten_Overige_zorg)
16WHERE {
17    # BIND($(vestigingsnummer) AS ?vestigingsnummer)
18    # BIND($(peildatum) AS ?peildatum)
19    BIND(?peildatum AS ?peildatum_argument)
20    
21    # Nieuwe vestigingsnummer triple
22    ?vestiging 
23        a onz-org:Vestiging ;
24        onz-g:identifiedBy ?vestigingsnummer_object .
25    ?vestigingsnummer_object
26        a onz-org:Vestigingsnummer ;
27        onz-g:hasDataValue ?vestigingsnummer .
28    
29    { 
30        ?indicatie a onz-zorg:IndicatieBesluit .
31    } UNION {
32        ?indicatie a onz-zorg:ForensischeIndicatieStelling .
33    }
34    
35    #selecteer de bijbehorende indicatie, om unieke clienten te kunnen bepalen
36    ?indicatie 
37        onz-g:startDatum ?start_indicatie ;
38        onz-g:isAbout ?client .
39    ?client a onz-g:Human .
40    OPTIONAL {?indicatie onz-g:eindDatum ?eind_indicatie}
41    FILTER(?peildatum_argument >= ?start_indicatie && (?peildatum_argument <= ?eind_indicatie || !BOUND(?eind_indicatie)))
42    
43    #selecteer de zorgprocessen die voldoen aan de inclusiecriteria
44    ?zorgproces
45        a onz-g:CureAndCareProcess ;
46        onz-g:definedBy ?indicatie ;
47        onz-g:hasPerdurantLocation/onz-g:partOf* ?vestiging ;
48        onz-g:startDatum ?start_zorgproces .
49    OPTIONAL {?zorgproces onz-g:eindDatum ?eind_zorgproces}
50    FILTER (?start_zorgproces <= ?peildatum_argument && ((?eind_zorgproces >= ?peildatum_argument)||(!BOUND(?eind_zorgproces))))
51    
52    #Per financieringsstroom
53    OPTIONAL {
54        ?indicatie a onz-zorg:WlzIndicatie .
55        BIND(1 AS ?wlz) .
56    }
57    OPTIONAL {
58        ?indicatie a onz-zorg:ZvwIndicatie .
59        BIND(1 AS ?zvw) .
60    }
61    
62}
63