1.2. Aantal zorgmedewerkers per kwalificatieniveau

Concepten

• Mens
• ODB Kwalificatiewaarde
• Vestiging
• Vestigingsnummer
• Zorgverlener (functie)

Relaties

• deel van
• gaat over
• geïdentificeerd door
• heeft eigenschap of kenmerk
• heeft eigenschapswaarde
• heeft opdrachtnemer

Eigenschappen

• einddatum
• heeft datawaarde
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: VWS 1.2
2# Parameters: $(vestigingsnummer), $(peildatum)
3# Ontologie: versie 2.0.1 of nieuwer
4
5PREFIX onz-g: <http://purl.org/ozo/onz-g#>
6PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
7PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
8PREFIX onz-org: <http://purl.org/ozo/onz-org#>
9PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
10PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
11PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
12
13SELECT ?kwalificatieniveau (COUNT (DISTINCT ?persoon) AS ?aantal_personen)
14{
15    BIND ($(vestigingsnummer) AS ?vestigingsnummer) 
16    ?vest_nr_uri
17        a onz-org:Vestigingsnummer ;
18        onz-g:hasDataValue ?vestigingsnummer .
19    ?vestiging
20        a onz-org:Vestiging ;
21        onz-g:identifiedBy ?vest_nr_uri.
22    BIND($(peildatum) AS ?peildatum)
23
24    ?functie 
25        a onz-pers:ZorgverlenerFunctie ;
26        a/onz-g:hasQuality/onz-g:hasQualityValue ?functie_niveau ;
27        onz-g:startDatum ?start_functie .
28    OPTIONAL {?functie a onz-pers:ZorgverlenerFunctie ;
29                onz-g:eindDatum ?eind_functie}
30    FILTER (?start_functie <= ?peildatum && ((?eind_functie >= ?peildatum)||(!BOUND(?eind_functie))))
31    ?overeenkomst
32        onz-g:isAbout ?functie ;
33        onz-pers:heeftOpdrachtnemer ?persoon ;
34        onz-g:isAbout/onz-g:partOf* ?vestiging .
35    ?persoon
36        a onz-g:Human .
37    ?functie_niveau 
38        a onz-pers:ODBKwalificatieWaarde .
39    {
40        ?functie_niveau
41            rdfs:label ?kwalificatieniveau .
42    } UNION {
43        BIND ('Totaal' AS ?kwalificatieniveau)
44    }
45}
46GROUP BY ?kwalificatieniveau
47ORDER BY ?kwalificatieniveau