1.6. Aantal leerlingen

Concepten

• Arbeidsovereenkomst beroeps begeleidende leerweg
• Bedrijf
• Mens
• Vestiging
• Vestigingsnummer

Relaties

• deel van
• gaat over
• geïdentificeerd door
• heeft opdrachtnemer
• vestiging van

Eigenschappen

• einddatum
• heeft datawaarde
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: VWS 1.6
2# Parameters: $(peildatum)
3# Ontologie: versie 2.0.0 of nieuwer
4
5PREFIX onz-g: <http://purl.org/ozo/onz-g#>
6PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
7PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
8PREFIX onz-org: <http://purl.org/ozo/onz-org#>
9PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
10PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
11PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
12
13SELECT 
14    ?vestiging 
15    (COUNT (DISTINCT ?persoon) AS ?Aantal_BBL)
16{
17    #Bepaal de peildatum
18    BIND($(peildatum) AS ?peildatum)
19    
20    #Selecteer alle personeelsleden met een BBL overeenkomst binnen de meetperiode
21    ?persoon
22        a onz-g:Human ;
23        ^onz-pers:heeftOpdrachtnemer ?overeenkomst .
24    ?overeenkomst
25        a onz-pers:ArbeidsOvereenkomstBBL ;
26        onz-g:isAbout ?functie ;
27        onz-g:isAbout ?locatie ;
28        onz-g:startDatum ?start_overeenkomst .
29        OPTIONAL {?overeenkomst onz-g:eindDatum ?eind_overeenkomst}
30        FILTER (?start_overeenkomst <= ?peildatum && ((?eind_overeenkomst >= ?peildatum)||(!BOUND(?eind_overeenkomst))))
31
32    #Bepaal de vestiging waar de werkzaamheden verricht worden volgens de werkovereenkomst
33    {
34        ?locatie 
35            onz-g:partOf* ?vestiging_uri .
36        ?vestiging_uri 
37            a onz-org:Vestiging ;
38            onz-g:identifiedBy ?vest_nr .
39        ?vest_nr
40            a onz-org:Vestigingsnummer ;
41            onz-g:hasDataValue ?vestiging .
42    } UNION {
43        #Includeer ook de organisatie als geheel en label deze als vestiging
44        ?locatie onz-g:partOf*/onz-org:vestigingVan ?organisatie_uri .
45        ?organisatie_uri 
46            a onz-g:Business ;
47            rdfs:label ?Organisatie .
48        BIND(CONCAT('Totaal ',?Organisatie) AS ?vestiging)
49    }
50} 
51GROUP BY ?vestiging