1.3. Percentage arbeidsovereenkomsten voor bepaalde tijd op een peildatum

Concepten

• Arbeidsovereenkomst
• Arbeidsovereenkomst bepaalde tijd
• Vestiging
• Vestigingsnummer

Relaties

• deel van
• gaat over
• geïdentificeerd door
• heeft opdrachtnemer

Eigenschappen

• einddatum
• heeft datawaarde
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: VWS 1.3
2# Parameters: $(peildatum)
3# Ontologie: versie 2.0.0 of nieuwer
4
5PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
6PREFIX onz-g: <http://purl.org/ozo/onz-g#>
7PREFIX onz-org: <http://purl.org/ozo/onz-org#>
8PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
9PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
10
11select 
12	?vestiging
13	(COUNT(DISTINCT ?personeel_bepaalde_tijd) AS ?aantal_bepaalde_tijd) 
14	(COUNT(DISTINCT ?personeel) AS ?aantal_onbepaalde_tijd) 
15	(COUNT(DISTINCT ?personeel_bepaalde_tijd)/(COUNT(DISTINCT ?personeel_bepaalde_tijd)+COUNT(DISTINCT ?personeel))*100 AS ?percentage_bepaalde_tijd)
16WHERE {     
17    # definieer peildatum
18    BIND($(peildatum) AS ?peildatum)
19    {
20        # selecteer personen met arbeidsovereenkomst bepaalde tijd
21        ?arbeidsovereenkomst a onz-pers:ArbeidsOvereenkomstBepaaldeTijd ;
22        	onz-g:startDatum ?start_overeenkomst ;
23        	onz-g:isAbout ?locatie ;
24        	onz-pers:heeftOpdrachtnemer ?personeel_bepaalde_tijd .
25        OPTIONAL {?arbeidsovereenkomst onz-g:eindDatum ?eind_overeenkomst}
26        
27        # bepaal de vestiging waar de werkzaamheden verricht worden volgens de werkovereenkomst
28        ?locatie 
29            onz-g:partOf* ?vestiging_uri .
30        ?vestiging_uri 
31            a onz-org:Vestiging ;
32            onz-g:identifiedBy ?vest_nr .
33        ?vest_nr
34            a onz-org:Vestigingsnummer ;
35            onz-g:hasDataValue ?vestiging .
36    } 
37    UNION
38    {
39        # selecteer personen met arbeidsovereenkomst
40        ?arbeidsovereenkomst a onz-pers:ArbeidsOvereenkomst ;
41        	onz-g:startDatum ?start_overeenkomst ;
42        	onz-g:isAbout ?locatie ;
43        	onz-pers:heeftOpdrachtnemer ?personeel .
44        OPTIONAL {?arbeidsovereenkomst onz-g:eindDatum ?eind_overeenkomst}
45        
46        # bepaal de vestiging waar de werkzaamheden verricht worden volgens de werkovereenkomst
47        ?locatie 
48            onz-g:partOf* ?vestiging_uri .
49        ?vestiging_uri 
50            a onz-org:Vestiging ;
51            onz-g:identifiedBy ?vest_nr .
52        ?vest_nr
53            a onz-org:Vestigingsnummer ;
54            onz-g:hasDataValue ?vestiging .
55    } 
56    # filter op peildatum
57    FILTER (?start_overeenkomst <= ?peildatum && (!BOUND(?eind_overeenkomst) || ?eind_overeenkomst >= ?peildatum))
58}
59GROUP BY ?vestiging