1.7. Aantal verloonde uren per kwartaal

Concepten

• Arbeidsovereenkomst
• Bedrijf
• Verloonde periode
• Vestiging
• Vestigingsnummer
• Zorgverlener (functie)

Relaties

• deel van
• definieert
• gaat over
• geïdentificeerd door
• heeft eigenschap of kenmerk
• heeft eigenschapswaarde
• heeft meeteenheid
• heeft opdrachtnemer
• vestiging van

Eigenschappen

• einddatum
• heeft datawaarde
• startdatum

Instanties

• Uur

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: VWS 1.7
2# Parameters: $(kwartaal)
3# Ontologie: versie 2.0.0 of nieuwer
4
5PREFIX onz-g: <http://purl.org/ozo/onz-g#>
6PREFIX onz-fin: <http://purl.org/ozo/onz-fin#>
7PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
8PREFIX onz-org: <http://purl.org/ozo/onz-org#>
9PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
10PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
11PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
12
13
14SELECT  
15	?vestiging
16	(SUM(?zorg * ?verloonde_uren) AS ?zorg_gerelateerde_uren)
17	(SUM(?niet_zorg * ?verloonde_uren) AS ?niet_zorg_gerelateerde_uren)
18{
19    # selecteer kwartaal 
20    BIND($(kwartaal) AS ?kwartaal)
21    BIND(
22        IF(?kwartaal = 'Q1', '2022-01-01'^^xsd:date, 
23        IF(?kwartaal = 'Q2', '2022-04-01'^^xsd:date,
24        IF(?kwartaal = 'Q3', '2022-07-01'^^xsd:date,
25        IF(?kwartaal = 'Q4', '2022-10-01'^^xsd:date, 
26        '')))) AS ?start_periode)
27    BIND((?start_periode + "P3M"^^xsd:duration - "P1D"^^xsd:duration) AS ?eind_periode)
28
29    # selecteer overeenkomst met start en eind en filter binnen kwartaal
30    ?overeenkomst 
31        a onz-pers:ArbeidsOvereenkomst ;
32        onz-pers:heeftOpdrachtnemer ?persoon ;
33        onz-g:isAbout ?locatie ;
34        onz-g:startDatum ?overeenkomst_start .
35    OPTIONAL { ?overeenkomst onz-g:eindDatum ?eind_overeenkomst }
36    FILTER (?overeenkomst_start <= ?eind_periode && (!BOUND(?overeenkomst_eind) || ?overeenkomst_eind >= ?start_periode))
37    
38    # bepaal de vestiging waar de werkzaamheden verricht worden volgens de werkovereenkomst
39    {
40        ?locatie 
41            onz-g:partOf* ?vestiging_uri .
42        ?vestiging_uri 
43            a onz-org:Vestiging ;
44            onz-g:identifiedBy ?vest_nr .
45        ?vest_nr
46            a onz-org:Vestigingsnummer ;
47            onz-g:hasDataValue ?vestiging .
48    } UNION {
49        # includeer ook de organisatie als geheel en label deze als vestiging
50        ?locatie onz-g:partOf*/onz-org:vestigingVan ?organisatie_uri .
51        ?organisatie_uri 
52            a onz-g:Business ;
53            rdfs:label ?organisatie .
54        BIND(CONCAT('Totaal ',?organisatie) AS ?vestiging)
55    }
56	
57    # definieer of de verloonde uren voor een zorgfunctie zijn
58    OPTIONAL {
59        ?overeenkomst onz-g:isAbout ?zorgfunctie .
60        ?zorgfunctie a onz-pers:ZorgverlenerFunctie
61    }
62    # maak variabele waarmee of de verloonde uren vermenigvuldigd kunnen worden 
63    BIND(IF(BOUND(?zorgfunctie),1,0) AS ?zorg)
64	BIND(IF(?zorg=1,0,1) AS ?niet_zorg)
65
66    # selecteer de verloonde uren en filter binnen kwartaal
67    ?overeenkomst 
68        onz-g:defines [
69        a onz-fin:VerloondePeriode ;
70        onz-g:startDatum ?verloon_start;
71        onz-g:eindDatum ?verloon_eind ;
72        onz-g:hasQuality [
73            onz-g:hasQualityValue [
74                onz-g:hasUnitOfMeasure onz-g:Uur ;
75                onz-g:hasDataValue ?verloonde_uren
76            ] ;
77        ] ;
78    ] .
79   FILTER (?verloon_start <= ?eind_periode && (!BOUND(?verloon_eind) || ?verloon_eind >= ?start_periode))
80  } 
81GROUP BY ?vestiging