11 Wat zijn de afschrijvingen op immateriële en materiële vaste activa?

Concepten

• Grootboekpost
• Grootboekrekening
• Grootboekrubriek

Relaties

• deel van

Eigenschappen

• heeft datum
• heeftGeldBedrag

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Nza Kostprijs 11
2# Canonical id: MONO-0022 - "Wat zijn de afschrijvingen op immateriële en materiële vaste activa?"
3# Parameters: ?startperiode ?eindperiode
4# Ontologie: versie 3.0.0 of nieuwer
5# Vereist uitgebreide financiele dataset en RGS-zorg versie om te testen
6
7PREFIX onz-g: <http://purl.org/ozo/onz-g#>
8PREFIX onz-fin: <http://purl.org/ozo/onz-fin#>
9PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
10
11SELECT
12("Totaal organisatie" AS ?Indeling)
13("Totaal jaar" AS ?Periode)
14(IF(COUNT(?geld_bedrag_post) = 0, "Niet beschikbaar", (ROUND(SUM(?geld_bedrag_post) * 100) / 100)) AS ?Bedrag)
15WHERE {
16    # BIND("2024-01-01"^^xsd:date AS ?startperiode)
17    # BIND("2024-12-31"^^xsd:date AS ?eindperiode)
18
19    # >>> START BB: BB-011_grootboekpost_rubriek.rq
20    ?grootboekpost
21    a onz-fin:Grootboekpost ;
22    onz-fin:heeftGeldBedrag ?geld_bedrag_post ;
23    onz-g:hasDate ?boekingsdatum ;
24    onz-g:partOf ?rubriek .
25
26    # Behoud de grootboekpost alleen voor de meest specifieke rubriek,
27    # om eventuele dubbeltelling door de hiërarchische structuur rubriekcodes te voorkomen
28    FILTER NOT EXISTS {
29        ?grootboekpost onz-g:partOf ?specifiekereRubriek .
30        ?specifiekereRubriek onz-g:partOf+ ?rubriek .
31    }
32    # <<< END BB: BB-011_grootboekpost_rubriek.rq
33
34    # >>> START BB: BB-007_geldig_binnen_periode.rq
35    FILTER(?boekingsdatum >= ?startperiode && ?boekingsdatum <= ?eindperiode)
36    # <<< END BB: BB-007_geldig_binnen_periode.rq
37
38    # Vind de juiste rubrieken voor Prismant en RGS
39    {
40
41        # >>> START BB: BB-010_rubriek_rubriekcode.rq
42        VALUES ?rubriekType { onz-fin:Grootboekrubriek onz-fin:Grootboekrekening }
43        ?rubriek a ?rubriekType .
44        BIND(STRAFTER(STR(?rubriek), STR(onz-fin:)) AS ?rubriekCode)
45        # <<< END BB: BB-010_rubriek_rubriekcode.rq
46
47        # >>> START BB: BB-008_zorgkostenmapping_Prismant.rq
48        VALUES (?mappingPrefix ?kostenSoort) {
49            ("480" "Afschrijvingskosten immateriële vaste activa")
50            ("481" "Afschrijvingskosten materiële vaste activa (terreinvoorzieningen, gebouwen/verbouwingen, installaties, inventaris, vervoermiddelen, automatisering)")
51            ("482" "Afschrijvingskosten materiële vaste activa (terreinvoorzieningen, gebouwen/verbouwingen, installaties, inventaris, vervoermiddelen, automatisering)")
52            ("483" "Afschrijvingskosten materiële vaste activa (terreinvoorzieningen, gebouwen/verbouwingen, installaties, inventaris, vervoermiddelen, automatisering)")
53            ("484" "Afschrijvingskosten materiële vaste activa (terreinvoorzieningen, gebouwen/verbouwingen, installaties, inventaris, vervoermiddelen, automatisering)")
54            ("913000" "Afschrijvingen van niet in het dienstverleningsproces opgenomen vaste activa")
55        }
56        # <<< END BB: BB-008_zorgkostenmapping_Prismant.rq
57
58        # >>> START BB: BB-015_rubriekcode_mappingprefix.rq
59        FILTER(STRSTARTS(?rubriekCode, ?mappingPrefix))
60        # <<< END BB: BB-015_rubriekcode_mappingprefix.rq
61
62    }
63    UNION
64    {
65
66        # >>> START BB: BB-010_rubriek_rubriekcode.rq
67        VALUES ?rubriekType { onz-fin:Grootboekrubriek onz-fin:Grootboekrekening }
68        ?rubriek a ?rubriekType .
69        BIND(STRAFTER(STR(?rubriek), STR(onz-fin:)) AS ?rubriekCode)
70        # <<< END BB: BB-010_rubriek_rubriekcode.rq
71
72        # >>> START BB: BB-009_zorgkostenmapping_RGS_zorg_3_8.rq
73        VALUES (?rubriekCodeRGS ?kostenSoort) {
74            ("WAfsAiv" "Afschrijvingen op immateriële vaste activa")
75            ("WAfsAmv" "Afschrijvingen op materiële vaste activa")
76            ("WAfsDae" "Afschrijvingen op immateriële en materiële vaste activa")
77        }
78        # <<< END BB: BB-009_zorgkostenmapping_RGS_zorg_3_8.rq
79
80        # >>> START BB: BB-015_rubriekcode_mappingprefix.rq
81        FILTER(STRSTARTS(?rubriekCode, ?rubriekCodeRGS))
82        # <<< END BB: BB-015_rubriekcode_mappingprefix.rq
83
84    }
85}
86