30 Wat is het aantal leveringen en het gedeclareerde bedrag van Zorg in Natura per combinatie van Wlz-Prestatiecode, tarief en tariefeenheid?

Concepten

• Leveringsvorm
• Wlz-indicatie
• ZorgDeclaratie
• ZorgEnVerpleegProces

Relaties

• gaat over
• gedefinieerd door
• heeft deel

Eigenschappen

• einddatum
• goedgekeurd
• heeft datum
• heeftAantal
• heeftGeldBedrag
• heeftTarief
• heeftTariefEenheid
• heeftZorgPrestatieCode
• startdatum

Instanties

• Verblijf in een instelling
• Volledig pakket thuis

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Nza Kostprijs 30
2# Canonical id: MONO-0038 - "Wat is het aantal leveringen en het gedeclareerde bedrag van Zorg in Natura per combinatie van Wlz-Prestatiecode, tarief en tariefeenheid?"
3# Parameters: ?startperiode ?eindperiode
4# Ontologie: versie 3.0.0 of nieuwer
5# Vereist uitgebreide financiele dataset en RGS-zorg versie om te testen
6
7PREFIX onz-g:    <http://purl.org/ozo/onz-g#>
8PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
9PREFIX onz-fin:  <http://purl.org/ozo/onz-fin#>
10PREFIX xsd:      <http://www.w3.org/2001/XMLSchema#>
11
12SELECT
13?Wlz_Prestatiecode
14?Tarief
15?Tarief_eenheid
16(SUM(?aantal) AS ?Aantal)
17(SUM(?bedrag) AS ?Bedrag)
18WHERE {
19    # Dedup: een declaratie telt één keer, ongeacht hoeveel paden
20    # (zorgproces × indicatie × leveringsvorm) er naar leiden.
21    {
22        SELECT DISTINCT ?declaratie ?Wlz_Prestatiecode ?Tarief ?Tarief_eenheid ?aantal ?bedrag
23        WHERE {
24            #BIND("2024-01-01"^^xsd:date AS ?startperiode)
25            #BIND("2024-12-31"^^xsd:date AS ?eindperiode)
26
27            # Stap 1: Selecteer goedgekeurde declaraties in meetperiode
28            ?declaratie
29            a onz-g:CareInvoice ;
30            onz-g:hasDate ?date ;
31            onz-g:goedgekeurd "true"^^xsd:boolean ;
32            onz-fin:heeftZorgPrestatieCode ?Wlz_Prestatiecode ;
33            onz-fin:heeftTarief ?Tarief ;
34            onz-fin:heeftTariefEenheid ?Tarief_eenheid ;
35            onz-fin:heeftAantal ?aantal ;
36            onz-fin:heeftGeldBedrag ?bedrag ;
37            onz-g:isAbout ?zorgproces .
38
39            # Stap 2: Filter op Wlz-indicatie via zorgproces (levering-leidend)
40            ?zorgproces a onz-g:CureAndCareProcess ;
41            onz-g:startDatum ?zorgproces_start ;
42            onz-g:definedBy ?indicatie .
43            OPTIONAL { ?zorgproces onz-g:eindDatum ?zorgproces_eind }
44            FILTER(?zorgproces_start <= ?eindperiode && (!BOUND(?zorgproces_eind) || ?zorgproces_eind >= ?startperiode))
45
46            ?indicatie a onz-zorg:WlzIndicatie ;
47            onz-g:hasPart ?leveringsvorm ;
48            onz-g:startDatum ?indicatie_start .
49            OPTIONAL { ?indicatie onz-g:eindDatum ?indicatie_eind }
50            FILTER(?indicatie_start <= ?eindperiode && (!BOUND(?indicatie_eind) || ?indicatie_eind >= ?startperiode))
51
52            # Stap 3: Filter op Zorg in Natura (Verblijf, VPT, MPT)
53            ?leveringsvorm a onz-zorg:Leveringsvorm .
54            FILTER(?leveringsvorm IN (onz-zorg:instelling, onz-zorg:vpt, onz-zorg:mpt))
55        }
56    }
57}
58GROUP BY ?Wlz_Prestatiecode ?Tarief ?Tarief_eenheid
59ORDER BY ?Wlz_Prestatiecode ?Tarief ?Tarief_eenheid
60