10.1. Wat is het percentage eenpersoonskamers?

Concepten

• Capaciteitswaarde
• Kwaliteit
• Mens
• Onverplaatsbaar artefact
• Vestiging
• Vestigingsnummer
• Wooneenheid

Relaties

• deel van
• deel van
• geïdentificeerd door
• heeft capaciteitsobject
• heeft eigenschap of kenmerk
• heeft eigenschapswaarde

Eigenschappen

• heeft datawaarde

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: RIVM 10.1
2# Parameters: 
3# Ontologie: versie 3.0.0 of nieuwer
4 
5PREFIX onz-g: <http://purl.org/ozo/onz-g#>
6PREFIX onz-org: <http://purl.org/ozo/onz-org#>
7PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
8
9SELECT 
10  (?vestiging AS ?Indeling)
11  (COUNT(?wooneenheid) AS ?Aantal_wooneenheden)
12  (SUM(IF(?unitCapacity = 1, 1, 0)) AS ?Aantal_éénpersoons_wooneenheden)
13  (ROUND(SUM(IF(?unitCapacity = 1, 1, 0)) * 10000 / COUNT(?wooneenheid)) / 100 AS ?Procent_éénpersoons_wooneenheden)
14WHERE {
15  {
16    SELECT ?vestiging ?wooneenheid (MAX(?waarde) AS ?unitCapacity)
17    WHERE {
18      ?wooneenheid 
19          a onz-org:WoonEenheid ;
20          onz-g:hasQuality ?cap .
21
22      ?cap
23          a onz-g:Quality ;
24          onz-g:hasQualityValue ?cap_waarde .
25
26      ?cap_waarde a onz-g:CapacityValue ;
27          onz-g:hasDataValue ?waarde ;
28          onz-g:hasCapacityObject onz-g:Human .
29
30      {
31        # Per vestiging
32        ?wooneenheid onz-g:partOf ?locatie .
33        ?locatie 
34            a onz-g:StationaryArtifact ;
35            onz-g:partOf* ?vestiging_uri .
36                
37        ?vestiging_uri a onz-org:Vestiging ;
38            onz-g:identifiedBy ?vest_nr .
39
40        ?vest_nr a onz-org:Vestigingsnummer ;
41            onz-g:hasDataValue ?vestiging .
42      }
43      UNION
44      {
45        # Totaal organisatie 
46        BIND("Totaal organisatie" AS ?vestiging)
47      }
48    }
49    GROUP BY ?vestiging ?wooneenheid
50  }
51}
52GROUP BY ?vestiging
53ORDER BY ?vestiging
54