14.3 Aantal cliënten met een Wlz-indicatie per zorgprofiel VV per leveringsvorm op een peildatum

Concepten

• Leveringsvorm
• Mens
• Onverplaatsbaar artefact
• Verpleegproces
• Vestiging
• Zorgkantoor regio

Relaties

• deel van
• gaat over
• gedefinieerd door
• geïdentificeerd door
• heeft deel
• heeft lokaliseerbaar gebied
• heeft perdurantlocatie
• opereert in regio

Eigenschappen

• einddatum
• indicatie behandeling
• startdatum

Instanties

• Modulair pakket thuis
• Persoonsgebonden budget
• VV Beschermd verblijf met intensieve palliatief-terminale zorg
• VV Beschermd wonen met intensieve dementiezorg
• VV Beschermd wonen met intensieve verzorging en verpleging
• VV Beschermd wonen met zeer intensieve zorg, vanwege specifieke aandoeningen, met de nadruk op begeleiding
• VV Beschermd wonen met zeer intensieve zorg, vanwege specifieke aandoeningen, met de nadruk op verzorging en verpleging
• VV Beschut wonen met intensieve begeleiding en uitgebreide verzorging
• VV Herstelgerichte behandeling met verpleging en verzorging
• Verblijf in een instelling
• Volledig pakket thuis

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Zorgkantoren 14.3
2# Parameters: ?peildatum, ?zorgkantoor
3# Ontologie: versie 3.0 of nieuwer
4
5PREFIX onz-g: <http://purl.org/ozo/onz-g#>
6PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
7PREFIX onz-org: <http://purl.org/ozo/onz-org#>
8PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
9PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
10PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
11
12SELECT
13	?zorgprofiel
14	(SUM(?max_vmb) AS ?verblijf_met_behandeling)
15	(SUM(?max_vzb) AS ?verblijf_zonder_behandeling)
16	(SUM(?max_vpt) AS ?volledig_pakket_thuis)
17	(SUM(?max_mpt) AS ?modulair_pakket_thuis)
18	(SUM(?max_pgb) AS ?persoonsgebonden_budget)
19	(SUM(?max_vmb) + SUM(?max_vzb) + SUM(?max_vpt) + SUM(?max_mpt) + SUM(?max_pgb) AS ?Totaal)
20{
21    {
22        SELECT
23            ?client
24            ?zorgprofiel
25            (MAX(?vmb) AS ?max_vmb)
26            (MAX(?vzb) AS ?max_vzb)
27            (MAX(?vpt) AS ?max_vpt)
28            (MAX(?mpt) AS ?max_mpt)
29            (MAX(?pgb) AS ?max_pgb)
30        WHERE
31        { 
32#            BIND ($(peildatum) AS ?peildatum)
33            VALUES ?zorgprofiel { onz-zorg:4VV onz-zorg:5VV onz-zorg:6VV onz-zorg:7VV onz-zorg:8VV onz-zorg:9BVV onz-zorg:10VV }
34
35            #selecteer de zorgprocessen op de (sub)locaties die voldoen aan de inclusiecriteria
36            ?zorgproces
37                a onz-zorg:NursingProcess ;
38                onz-g:definedBy ?indicatie ;
39                onz-g:hasPerdurantLocation ?locatie ;
40                onz-g:startDatum ?start_zorgproces .
41                OPTIONAL {?zorgproces onz-g:eindDatum ?eind_zorgproces}
42                FILTER (?start_zorgproces <= ?peildatum && ((?eind_zorgproces >= ?peildatum)||(!BOUND(?eind_zorgproces))))
43            ?locatie 
44                a onz-g:StationaryArtifact ;
45        	    onz-g:partOf* ?vestiging_uri .
46            ?vestiging_uri a onz-org:Vestiging ;
47                onz-g:hasLocalizableArea/onz-g:identifiedBy/onz-g:hasPart/onz-g:hasPart ?postcode_6 .
48                BIND(IRI(SUBSTR(STR(?postcode_6), 1, STRLEN(STR(?postcode_6)) - 2)) AS ?postcode)
49            ?pc_gebied 
50                onz-g:identifiedBy ?postcode ;
51                onz-g:partOf+ ?zk_regio .
52            ?zk_regio a onz-org:ZorgkantoorRegio .
53            ?zorgkantoor onz-g:hasOperatingRange ?zk_regio .
54
55            #selecteer de bijbehordene indicatie, om unieke clienten te kunnen bepalen
56            ?indicatie 
57                onz-g:hasPart ?zorgprofiel ;
58                onz-g:hasPart ?lv ;
59                onz-g:isAbout ?client .
60                OPTIONAL {?indicatie onz-zorg:heeftIndicatieBehandeling ?behandeling}
61                BIND(IF(BOUND(?behandeling), ?behandeling, "false"^^xsd:boolean) AS ?incl_behandeling)
62            ?client a onz-g:Human .
63            ?lv
64                a onz-zorg:Leveringsvorm .
65            BIND(IF(?lv = onz-zorg:instelling && ?incl_behandeling, 1, 0) AS ?vmb)
66            BIND(IF(?lv = onz-zorg:instelling && !?incl_behandeling, 1, 0) AS ?vzb)
67            BIND(IF(?lv = onz-zorg:vpt, 1, 0) AS ?vpt)
68            BIND(IF(?lv = onz-zorg:mpt, 1, 0) AS ?mpt)
69            BIND(IF(?lv = onz-zorg:pgb, 1, 0) AS ?pgb)
70        } 
71        GROUP BY ?client ?zorgprofiel
72    }
73}
74GROUP BY ?zorgprofiel
75