13.1 Hoeveel zorgverleners in loondienst zijn er ingestroomd?

Concepten

• Arbeidsovereenkomst
• Werkovereenkomst afspraak
• Zorgverlener (functie)

Relaties

• gaat over
• heeft deel
• heeft opdrachtnemer

Eigenschappen

• einddatum
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Zorgkantoren 13.1
2# Parameters: ?peildatum
3# Ontologie: versie 3.0 of nieuwer
4
5PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
6PREFIX onz-org: <http://purl.org/ozo/onz-org#>
7PREFIX onz-g: <http://purl.org/ozo/onz-g#>
8PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
9PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
10
11SELECT
12    ("Organisatie (gecontracteerd + algemeen)" AS ?Indeling)
13    (SUM(?noemer_waarde) AS ?Aantal_PIL_met_zorgfunctie)
14    (SUM(?teller_waarde) AS ?Aantal_ingestroomde_PIL_met_zorgfunctie)
15    (IF(
16        SUM(?noemer_waarde) = 0,
17        "Ongedefinieerd",
18        100 * (SUM(?teller_waarde) / SUM(?noemer_waarde))
19    ) AS ?Procent_zorggerelateerde_instroom_tov_totaal_zorggerelateerd)
20WHERE {
21    SELECT
22        ?werknemer
23        (IF(MAX(?op_peildatum) = 1, 1, 0) AS ?noemer_waarde)
24        (IF(MAX(?op_peildatum) = 1 && MAX(?op_peildatum_eerder) = 0, 1, 0) AS ?teller_waarde)
25    WHERE {
26        # BIND(xsd:date("2024-08-01") AS ?peildatum)
27
28        BIND((?peildatum - "P1Y"^^xsd:duration) AS ?peildatum_eerder)
29
30        # Bepaal filter voor definitie van overeenkomsten die geldig zijn voor personeelsleden
31        ?overeenkomst
32            a onz-pers:ArbeidsOvereenkomst ;
33            onz-pers:heeftOpdrachtnemer ?werknemer ;
34            onz-g:hasPart ?overeenkomst_afspraak .
35
36        ?overeenkomst_afspraak
37            a onz-pers:WerkOvereenkomstAfspraak ;
38            onz-g:isAbout ?functie ;
39            onz-g:startDatum ?start_afspraak .
40
41        ?functie
42            a onz-pers:ZorgverlenerFunctie .
43
44        OPTIONAL {
45            ?overeenkomst_afspraak onz-g:eindDatum ?eind_afspraak .
46        }
47
48        FILTER(
49            ?start_afspraak <= ?peildatum &&
50            (!BOUND(?eind_afspraak) ||?eind_afspraak >= ?peildatum_eerder)
51        )
52
53        BIND(
54            IF(?start_afspraak <= ?peildatum && (?eind_afspraak >= ?peildatum || !BOUND(?eind_afspraak)),
55            1,
56            0
57        ) AS ?op_peildatum)
58
59        BIND(
60            IF(?start_afspraak <= ?peildatum_eerder && (?eind_afspraak >= ?peildatum_eerder || !BOUND(?eind_afspraak)),
61            1,
62            0
63        ) AS ?op_peildatum_eerder)
64    }
65
66    GROUP BY ?werknemer
67}