13.4 Hoeveel personeel stroomt door naar een aflopend kwalificatieniveau?

Concepten

• Arbeidsovereenkomst
• ODB Kwalificatiewaarde
• Werkovereenkomst afspraak
• Zorgverlener (functie)

Relaties

• gaat over
• heeft deel
• heeft eigenschap of kenmerk
• heeft eigenschapswaarde
• heeft opdrachtnemer

Eigenschappen

• einddatum
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Zorgkantoren 13.4
2# Parameters: ?peildatum
3# Ontologie: versie 3.0 of nieuwer
4
5PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
6PREFIX onz-org: <http://purl.org/ozo/onz-org#>
7PREFIX onz-g: <http://purl.org/ozo/onz-g#>
8PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
9PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
10
11SELECT
12    ("Aantal:" AS ?Indeling)
13    (IF(SUM(?noemer_waarde) = 0, "Ongedefinieerd", 100 * SUM(?teller_waarde)/SUM(?noemer_waarde)) AS ?Procent_personeelsleden_met_een_aflopend_kwalificatieniveau)
14{
15    SELECT
16        (IF(?niveau_eerder > 0 && ?niveau_peildatum > 0, 1, 0) AS ?noemer_waarde)
17        (IF(?noemer_waarde = 1 && ?niveau_eerder > ?niveau_peildatum, 1, 0) AS ?teller_waarde)
18    {
19        SELECT
20            ?werknemer
21            (MAX(?op_peildatum) AS ?niveau_peildatum)
22            (MAX(?op_peildatum_eerder) AS ?niveau_eerder)
23        {
24            SELECT
25                ?werknemer
26                ?op_peildatum
27                ?op_peildatum_eerder
28            {   
29                # BIND(xsd:date("2024-05-12") AS ?peildatum)
30                BIND((?peildatum - "P3M"^^xsd:duration) AS ?peildatum_eerder)
31                
32                # Alle werknemers met een zorgverlenerfunctie
33                ?overeenkomst
34                    a onz-pers:ArbeidsOvereenkomst ;
35                    onz-pers:heeftOpdrachtnemer ?werknemer ;
36                    onz-g:hasPart ?overeenkomst_afspraak .
37                ?overeenkomst_afspraak
38                    a onz-pers:WerkOvereenkomstAfspraak ;
39                    onz-g:isAbout ?functie ;
40                    onz-g:startDatum ?start_afspraak .
41                ?functie 
42                    a onz-pers:ZorgverlenerFunctie ;
43                    onz-g:hasQuality /onz-g:hasQualityValue ?functie_niveau .
44                
45                OPTIONAL {
46                    ?overeenkomst_afspraak onz-g:eindDatum ?eind_afspraak
47                }
48                # selecteer kwalificatie niveau en converteer naar integer
49                ?functie_niveau
50                    a onz-pers:ODBKwalificatieWaarde ;
51                    rdfs:label ?niveau .
52                BIND(xsd:integer(REPLACE(?niveau, "\\D+", "")) AS ?niveau_number)
53                
54                # filter medewerkers met kwalificatieniveau 1 t/m 6
55                FILTER((?niveau_number >=1) && (?niveau_number <=6))
56
57                # filter de functies relevant tijdens de peildatum
58                BIND(IF(?start_afspraak <= ?peildatum && ((?eind_afspraak >= ?peildatum)||(!BOUND(?eind_afspraak))), ?niveau_number, 0) AS ?op_peildatum)
59                BIND(IF(?start_afspraak <= ?peildatum_eerder && ((?eind_afspraak >= ?peildatum_eerder)||(!BOUND(?eind_afspraak))), ?niveau_number, 0) AS ?op_peildatum_eerder)
60            }
61        }
62        GROUP BY ?werknemer
63    }
64}