1.1. Wat is het aantal cliënten met leveringsvorm verblijf?

Concepten

• Mens
• Vestiging
• Vestigingsnummer
• Wlz-indicatie
• ZorgEnVerpleegProces
• Zorgkantoor regio
• Zorgprofiel

Relaties

• deel van
• gaat over
• gedefinieerd door
• geïdentificeerd door
• heeft deel
• heeft lokaliseerbaar gebied
• heeft perdurantlocatie
• vestiging van

Eigenschappen

• einddatum
• heeft datawaarde
• startdatum

Instanties

• LG Wonen met begeleiding en enige verzorging
• LG Wonen met enige begeleiding en enige verzorging (2015)
• LG Wonen met enige begeleiding en verzorging (2015)
• VV Beschermd wonen met intensieve dementiezorg
• VV Beschermd wonen met intensieve verzorging en verpleging
• VV Beschermd wonen met zeer intensieve zorg, vanwege specifieke aandoeningen, met de nadruk op begeleiding
• VV Beschermd wonen met zeer intensieve zorg, vanwege specifieke aandoeningen, met de nadruk op verzorging en verpleging
• VV Beschut wonen met intensieve begeleiding en uitgebreide verzorging
• VV Herstelgerichte behandeling met verpleging en verzorging
• Verblijf in een instelling

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Actiz 1.1
2# Parameters: ?jaar ?kwartaal
3# Ontologie: versie 3.0 of nieuwer
4
5PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
6PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
7PREFIX onz-g: <http://purl.org/ozo/onz-g#>
8PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
9PREFIX onz-org: <http://purl.org/ozo/onz-org#>
10PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
11
12SELECT 
13	(?vestiging_waarde AS ?Indeling)
14	(?zk_regio_code AS ?Zorgkantoorregiocode)
15    (COUNT (DISTINCT ?client) AS ?Aantal_clienten)
16WHERE {
17    # BIND(2024 AS ?jaar)
18	# BIND("Q1" AS ?kwartaal)
19    
20    # Periode grenzen van kwartalen
21    # Blok afkomstig uit 12.1 van Inkoopondersteuning en beleidsontwikkeling
22    BIND(
23        IF(?kwartaal = 'Q1', xsd:date(CONCAT(STR(?jaar), '-01-01')),
24            IF(?kwartaal = 'Q2', xsd:date(CONCAT(STR(?jaar), '-04-01')),
25                IF(?kwartaal = 'Q3', xsd:date(CONCAT(STR(?jaar), '-07-01')),
26                    IF(?kwartaal = 'Q4', xsd:date(CONCAT(STR(?jaar), '-10-01')),
27                        '')))) AS ?start_periode)
28    BIND(?start_periode + "P3M"^^xsd:duration + "-P1D"^^xsd:duration AS ?eind_periode)
29    
30    # Domein is alleen volgende zorgprofielen (nu nog "Zorgzwaartepakketidentifier" in de FO)
31    VALUES ?zorgprofiel {
32        onz-zorg:4VV
33        onz-zorg:5VV
34        onz-zorg:6VV
35        onz-zorg:7VV
36        onz-zorg:8VV
37        onz-zorg:9VV
38        onz-zorg:9AVV
39        onz-zorg:9BVV
40        onz-zorg:1LG
41        onz-zorg:2LG
42        onz-zorg:3LG
43    }
44    
45    # WLZ indicaties
46    ?indicatie a onz-zorg:WlzIndicatie ;
47    			 # Met leveringsvorm verblijf
48                 onz-g:hasPart onz-zorg:instelling ;
49    			 onz-g:hasPart ?zorgprofiel ;
50                 onz-g:isAbout ?client ;
51    			 onz-g:startDatum ?start_indicatie .    
52                 
53    # Indicatie periodes die in de meetperiode vallen
54    OPTIONAL { ?indicatie onz-g:eindDatum ?eind_indicatie }
55    FILTER(?start_indicatie <= ?eind_periode && ((?eind_indicatie >= ?start_periode) || (!BOUND(?eind_indicatie))))
56
57    ?zorgprofiel a onz-zorg:ZorgProfiel .
58    ?client a onz-g:Human .
59    
60    # De bij de indicaties behorende zorgprocessen
61    ?zorgproces a onz-g:CureAndCareProcess ;
62                onz-g:definedBy ?indicatie ;
63                onz-g:hasPerdurantLocation/onz-g:partOf* ?vestiging ;
64                onz-g:startDatum ?start_zorgproces .
65    ?vestiging a onz-org:Vestiging .
66    
67    # Zorgproces periodes die in de meetperiode vallen
68    OPTIONAL { ?zorgproces onz-g:eindDatum ?eind_zorgproces }
69    FILTER(?start_zorgproces <= ?eind_periode && ((?eind_zorgproces >= ?start_periode) || (!BOUND(?eind_zorgproces))))
70    
71    # Koppel die cliënt aan een vestiging
72	{  
73        ?vestiging onz-g:identifiedBy ?vest_nr .    	
74        ?vest_nr a onz-org:Vestigingsnummer ;
75        # De numerieke code van de vestiging die de input vormt voor de eerste kolom, volgens FO:
76        		   onz-g:hasDataValue ?vestiging_waarde .
77        
78        # Postcode ophalen van vestiging, en numeriek deel er uit halen
79        ?vestiging onz-g:hasLocalizableArea/onz-g:identifiedBy/onz-g:hasPart/onz-g:hasPart ?postcode_6 .
80        BIND(IRI(SUBSTR(STR(?postcode_6), 1, STRLEN(STR(?postcode_6)) - 2)) AS ?postcode)
81
82        # Zorgkantoor regio code afleiden
83        ?pc_gebied onz-g:identifiedBy ?postcode ;
84                   onz-g:partOf+ ?zk_regio .
85        ?zk_regio a onz-org:ZorgkantoorRegio .
86        BIND(IF(BOUND(?zk_regio), STRAFTER(STR(?zk_regio), "/onz-org/"), ?unbound) AS ?zk_regio_code)
87    } 
88    UNION 
89    {
90        	# Includeer ook de organisatie als geheel en label deze als "Totaal organisatie"
91        	?vestiging onz-org:vestigingVan ?organisatie_uri .
92        	BIND("Totaal organisatie" AS ?vestiging_waarde) .
93    }     
94} 
95GROUP BY ?vestiging_waarde ?zk_regio_code
96ORDER BY ?Indeling