1.5. Wat is het aantal cliënten met crisiszorg?

Concepten

• Vestigingsnummer
• Wlz-indicatie
• ZorgDeclaratie
• Zorgkantoor regio
• Zorgproces

Relaties

• deel van
• gaat over
• gedefinieerd door
• geïdentificeerd door
• heeft deel
• heeft deelnemer
• heeft lokaliseerbaar gebied
• heeft perdurantlocatie
• vestiging van

Eigenschappen

• einddatum
• goedgekeurd
• heeft datawaarde
• heeftZorgPrestatieCode
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: ActiZ 1.5
2# Parameters: ?jaar ?kwartaal
3# Ontologie: versie 3.0.0 of nieuwer
4
5PREFIX onz-g: <http://purl.org/ozo/onz-g#>
6PREFIX onz-org: <http://purl.org/ozo/onz-org#>
7PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
8PREFIX onz-fin: <http://purl.org/ozo/onz-fin#>
9PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
10PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
11
12SELECT (?vestiging_waarde AS ?Indeling) (?zk_regio_code AS ?Zorgkantoorregiocode) (COUNT(DISTINCT ?client) AS ?Aantal_cliënten)
13{
14	#BIND(2024 AS ?jaar)
15	#BIND("Q1" AS ?kwartaal)
16    
17    # Periode grenzen van kwartalen
18    BIND(
19        IF(?kwartaal = 'Q1', xsd:date(CONCAT(STR(?jaar), '-01-01')),
20            IF(?kwartaal = 'Q2', xsd:date(CONCAT(STR(?jaar), '-04-01')),
21                IF(?kwartaal = 'Q3', xsd:date(CONCAT(STR(?jaar), '-07-01')),
22                    IF(?kwartaal = 'Q4', xsd:date(CONCAT(STR(?jaar), '-10-01')),
23                        '')))) AS ?start_periode)
24    BIND(?start_periode + "P3M"^^xsd:duration + "-P1D"^^xsd:duration AS ?eind_periode)
25
26    VALUES ?prestatiecode { 
27        "Z110"
28        "Z560"
29    }
30    
31    ?declaratie
32        a onz-g:CareInvoice ;
33        onz-fin:heeftZorgPrestatieCode ?prestatiecode ;
34        onz-g:goedgekeurd "true"^^xsd:boolean ;
35        onz-g:isAbout ?zorgproces .
36    ?zorgproces
37        a onz-zorg:ZorgProces ;
38        onz-g:hasParticipant ?client ;
39        onz-g:startDatum ?start_zorgproces ;
40        onz-g:definedBy ?indicatie ;
41        onz-g:hasPerdurantLocation/onz-g:partOf* ?vestiging ;
42    OPTIONAL { ?zorgproces onz-g:eindDatum ?eind_zorgproces }
43    FILTER(?start_zorgproces <= ?eind_periode && ((?eind_zorgproces >= ?start_periode) || (!BOUND(?eind_zorgproces))))
44  
45    # Indicatie link en filter binnen peildatum
46    ?indicatie a onz-zorg:WlzIndicatie ;
47        onz-g:startDatum ?start_indicatie ;
48        onz-g:isAbout ?client ;
49    OPTIONAL { ?indicatie onz-g:eindDatum ?eind_indicatie }
50    FILTER(?start_indicatie <= ?eind_periode && 
51        ((?eind_indicatie >= ?start_periode) || !BOUND(?eind_indicatie)))
52     
53         # Koppel die cliënt aan een vestiging
54	{  
55        ?vestiging onz-g:identifiedBy ?vest_nr .    	
56        ?vest_nr a onz-org:Vestigingsnummer ;
57        # De numerieke code van de vestiging die de input vormt voor de eerste kolom, volgens FO:
58        		   onz-g:hasDataValue ?vestiging_waarde .
59        
60        # Postcode ophalen van vestiging, en numeriek deel er uit halen
61        ?vestiging onz-g:hasLocalizableArea/onz-g:identifiedBy/onz-g:hasPart/onz-g:hasPart ?postcode_6 .
62        BIND(IRI(SUBSTR(STR(?postcode_6), 1, STRLEN(STR(?postcode_6)) - 2)) AS ?postcode)
63
64        # Zorgkantoor regio code afleiden
65        ?pc_gebied onz-g:identifiedBy ?postcode ;
66                   onz-g:partOf+ ?zk_regio .
67        ?zk_regio a onz-org:ZorgkantoorRegio .
68        BIND(IF(BOUND(?zk_regio), STRAFTER(STR(?zk_regio), "/onz-org/"), ?unbound) AS ?zk_regio_code)
69    } 
70    UNION 
71    {
72        # Includeer ook de organisatie als geheel en label deze als "Totaal organisatie"
73        ?vestiging onz-org:vestigingVan ?organisatie_uri .
74        BIND("Totaal organisatie" AS ?vestiging_waarde) .
75    }   
76}
77GROUP BY ?vestiging_waarde ?zk_regio_code
78ORDER BY ?vestiging_waarde 
79