3.1. Wat is het aantal personen dat bij de zorgaanbieder kan wonen?

Concepten

• Capaciteitswaarde
• Kwaliteit
• Mens
• Onverplaatsbaar artefact
• Vestiging
• Vestigingsnummer
• Wooneenheid
• Zorgkantoor regio

Relaties

• deel van
• deel van
• geïdentificeerd door
• heeft capaciteitsobject
• heeft deel
• heeft eigenschap of kenmerk
• heeft eigenschapswaarde
• heeft lokaliseerbaar gebied
• vestiging van

Eigenschappen

• heeft datawaarde

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Actiz 3.1 
2# Parameters: 
3# Ontologie: versie 2.2.0 of nieuwer
4PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
5PREFIX onz-org: <http://purl.org/ozo/onz-org#>
6PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
7PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
8PREFIX onz-g: <http://purl.org/ozo/onz-g#>
9
10# Buitenste query
11# Omdat hier sum staat moeten we weer group by doen 
12SELECT 
13(?vestiging AS ?Indeling)
14(?zk_regio_code AS ?Zorgkantoorregiocode)
15(SUM(?unitCapacity) AS ?Capaciteit_aantal_bewoners)
16WHERE 
17{		
18    # Binnenste query 
19    # We moeten deze query groupby doen zodat je MAX() can doen op unitCapacity. 
20    # Dit filtert gelijk ook wooneenheden weg die geen capacity in de data hebben gedefinieerd
21    SELECT ?vestiging ?wooneenheid (MAX(?waarde) AS ?unitCapacity) ?zorgkantoor_vestiging ?zk_regio_code 		
22    WHERE 
23    {
24        ?wooneenheid 
25            a onz-org:WoonEenheid ;
26        	onz-g:hasQuality ?cap ;
27        	onz-g:partOf ?locatie .
28        ?cap
29            a onz-g:Quality ;
30        	onz-g:hasQualityValue ?cap_waarde .
31        ?cap_waarde 
32            a onz-g:CapacityValue ;
33        	onz-g:hasDataValue ?waarde ;
34        	onz-g:hasCapacityObject onz-g:Human .
35		?locatie
36            a onz-g:StationaryArtifact ;
37            onz-g:partOf* ?vestiging_uri .
38
39        {
40            ?vestiging_uri 
41            a onz-org:Vestiging ;
42            onz-g:hasLocalizableArea/onz-g:identifiedBy/onz-g:hasPart/onz-g:hasPart ?postcode_6 .
43        
44        	BIND(IRI(SUBSTR(STR(?postcode_6), 1, STRLEN(STR(?postcode_6)) - 2)) AS ?postcode)
45        	?pc_gebied
46                onz-g:identifiedBy ?postcode ;
47                onz-g:partOf+ ?zk_regio .
48        
49        	?zk_regio a onz-org:ZorgkantoorRegio .
50                ?vestiging_uri onz-g:identifiedBy ?vest_nr .
51                ?vest_nr a onz-org:Vestigingsnummer ;
52                onz-g:hasDataValue ?vestiging .
53            BIND(STRAFTER(STR(?zk_regio), "onz-org/") AS ?zk_regio_code)
54        } 
55        UNION 
56        {
57            # Includeer ook de organisatie als geheel en label deze als vestiging
58            ?vestiging_uri onz-org:vestigingVan ?organisatie_uri .
59            BIND("Totaal organisatie" AS ?vestiging)
60            BIND("n.v.t." AS ?zk_vestiging)
61        }
62        BIND(IF(!BOUND(?zk_vestiging), ?zorgkantoor, ?zk_vestiging) AS ?zorgkantoor_vestiging)
63
64    }
65    GROUP BY ?vestiging ?wooneenheid ?zorgkantoor_vestiging ?zk_regio_code 
66    
67}
68GROUP BY ?vestiging ?zk_regio_code 
69ORDER BY ?vestiging ?zk_regio_code