12.2 Wat is de verzuimfrequentie (incl. zwangerschapsverlof)?

Concepten

• Arbeidsovereenkomst
• Onverplaatsbaar artefact
• Vestiging
• Vestigingsnummer
• Werkovereenkomst afspraak
• Ziekteperiode
• Zorgkantoor regio
• Zwangerschapsverlof

Relaties

• deel van
• gaat over
• gedefinieerd door
• geïdentificeerd door
• heeft deel
• heeft lokaliseerbaar gebied
• heeft opdrachtnemer
• opereert in regio
• vestiging van

Eigenschappen

• einddatum
• heeft datawaarde
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Zorgkantoren 12.2
2# Parameters: ?jaar, ?kwartaal, ?zorgkantoor
3# Ontologie: versie 3.0 of nieuwer
4
5PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
6PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
7PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
8PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
9PREFIX onz-g: <http://purl.org/ozo/onz-g#>
10PREFIX onz-org: <http://purl.org/ozo/onz-org#>
11PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
12
13SELECT 
14    (?vestiging AS ?Indeling)
15    # ?zorgkantoor_vestiging
16    (COUNT(DISTINCT ?persoon) AS ?Aantal_personeelsleden_in_loondienst)
17    (SUM(?meldingen) AS ?Aantal_nieuwe_ziekmeldingen)
18    (SUM(?meldingen) / COUNT(DISTINCT ?persoon) * 100 AS ?Verzuimfrequentie_incl_zwangerschap)
19WHERE {
20    {
21        SELECT 
22            ?persoon
23            ?vestiging
24            # ?zorgkantoor_vestiging
25            (COUNT(DISTINCT ?ziekteperiode) AS ?meldingen)
26        WHERE {
27            # BIND(2023 AS ?jaar)
28            # BIND("Q1" AS ?kwartaal)
29            # BIND(onz-org:ZorgkantoorMenzis AS ?zorgkantoor)
30
31            BIND(
32                IF(?kwartaal = 'Q1', xsd:date(CONCAT(STR(?jaar), '-01-01')),
33                IF(?kwartaal = 'Q2', xsd:date(CONCAT(STR(?jaar), '-04-01')),
34                IF(?kwartaal = 'Q3', xsd:date(CONCAT(STR(?jaar), '-07-01')),
35                IF(?kwartaal = 'Q4', xsd:date(CONCAT(STR(?jaar), '-10-01')),
36                '')))) AS ?start_periode)
37            BIND(?start_periode + "P3M"^^xsd:duration + "-P1D"^^xsd:duration AS ?eind_periode)
38
39            ?overeenkomst 
40                a onz-pers:ArbeidsOvereenkomst ; # personeel in loondienst
41                onz-pers:heeftOpdrachtnemer ?persoon ;
42                onz-g:hasPart ?overeenkomst_afspraak .
43
44            ?overeenkomst_afspraak
45                a onz-pers:WerkOvereenkomstAfspraak ;
46                onz-g:isAbout ?locatie ;
47                onz-g:startDatum ?start_afspraak .
48            OPTIONAL { ?overeenkomst_afspraak onz-g:eindDatum ?eind_afspraak }
49            FILTER (?start_afspraak <= ?eind_periode && ((!BOUND(?eind_afspraak)) || (?eind_afspraak >= ?start_periode)))
50
51            ?locatie 
52                a onz-g:StationaryArtifact ;
53                onz-g:partOf* ?vestiging_uri .
54            ?vestiging_uri a onz-org:Vestiging ;
55                onz-g:hasLocalizableArea/onz-g:identifiedBy/onz-g:hasPart/onz-g:hasPart ?postcode_6 .
56            BIND(IRI(SUBSTR(STR(?postcode_6), 1, STRLEN(STR(?postcode_6)) - 2)) AS ?postcode)
57            ?pc_gebied 
58                onz-g:identifiedBy ?postcode ;
59                onz-g:partOf+ ?zk_regio .
60            ?zk_regio a onz-org:ZorgkantoorRegio .
61            ?zorgkantoor onz-g:hasOperatingRange ?zk_regio .
62
63            {     
64                ?vestiging_uri onz-g:identifiedBy ?vest_nr .    	
65                ?vest_nr a onz-org:Vestigingsnummer ;
66                    onz-g:hasDataValue ?vestiging .
67            } UNION {
68                # Includeer ook de organisatie als geheel en label deze als vestiging
69                ?vestiging_uri onz-org:vestigingVan ?organisatie_uri .
70                BIND("Organisatie (gecontracteerd + algemeen)" AS ?vestiging)
71                BIND("n.v.t." AS ?zk_vestiging)
72            }
73            BIND(IF(!BOUND(?zk_vestiging), ?zorgkantoor, ?zk_vestiging) AS ?zorgkantoor_vestiging)
74
75            
76            #Aantal ziekte meldingen
77            VALUES ?type_verzuim {
78                onz-pers:ZiektePeriode
79                onz-pers:ZwangerschapsVerlof
80            }
81            OPTIONAL {
82                ?ziekteperiode a ?type_verzuim .
83
84                ?ziekteperiode 
85                    onz-g:definedBy ?overeenkomst ;
86                    onz-g:startDatum ?start_ziekte_periode .
87
88                # Alleen nieuwe ziekmeldingen binnen meetperiode
89                FILTER(?start_ziekte_periode >= ?start_periode && ?start_ziekte_periode <= ?eind_periode)
90
91                # Zorg dat ziekmelding valt binnen looptijd van de afspraak 
92                FILTER(?start_ziekte_periode >= ?start_afspraak && ( !BOUND(?eind_afspraak) || ?start_ziekte_periode <= ?eind_afspraak ))
93            }            
94        }
95        GROUP BY ?persoon ?vestiging ?zorgkantoor_vestiging
96    }
97}
98GROUP BY ?vestiging ?zorgkantoor_vestiging
99ORDER BY ?vestiging ?zorgkantoor_vestiging
100