15.4.3 Hoeveel Wlz-cliënten met zorgprofiel VV zijn er per leveringsvorm?

Concepten

• Langdurige zorg sector
• Leveringsvorm
• Mens
• Onverplaatsbaar artefact
• Vestiging
• Wlz-indicatie
• ZorgEnVerpleegProces
• Zorgkantoor regio

Relaties

• deel van
• gaat over
• gedefinieerd door
• geïdentificeerd door
• heeft deel
• heeft lokaliseerbaar gebied
• heeft perdurantlocatie
• opereert in regio
• vestiging van

Eigenschappen

• einddatum
• heeft datawaarde
• startdatum

Instanties

• Modulair pakket thuis
• Persoonsgebonden budget
• Verblijf in een instelling
• Volledig pakket thuis

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Zorgkantoren 15.4.3
2# Parameters: ?peildatum ?zorgkantoor
3# Ontologie: versie 2.0.0 of nieuwer
4
5PREFIX onz-org: <http://purl.org/ozo/onz-org#>
6PREFIX onz-g: <http://purl.org/ozo/onz-g#>
7PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
8PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
9
10SELECT 
11    (?Organisatieonderdeel AS ?Indeling)
12    (SUM(IF(?lv = onz-zorg:instelling, 1, 0)) AS ?Verblijf)
13    (SUM(IF(?lv = onz-zorg:vpt, 1, 0)) AS ?VPT)
14    (SUM(IF(?lv = onz-zorg:mpt, 1, 0)) AS ?MPT)
15    (SUM(IF(?lv = onz-zorg:pgb, 1, 0)) AS ?PGB)
16
17WHERE {
18    	# Deze binnenste query zorgt ervoor dat alleen unieke clienten per organisatieonderdeel en leveringsvorm in de results komen en zo dus dat klanten met dubbele indicaties van dezelfde sector niet dubbel worden geteld in de summatie hierboven
19        SELECT DISTINCT  
20            ?Organisatieonderdeel 
21            ?client 
22            ?lv
23        WHERE {
24
25#            BIND("2024-01-01"^^xsd:date AS ?peildatum)
26
27            # Selecteer de zorgprocessen en indicaties 
28            ?zorgproces
29                a onz-g:CureAndCareProcess ;
30                onz-g:definedBy ?indicatie ;
31                onz-g:hasPerdurantLocation/onz-g:partOf* ?locatie ;
32                onz-g:startDatum ?start_zorgproces .
33            
34            OPTIONAL {?zorgproces onz-g:eindDatum ?eind_zorgproces}
35            FILTER (?start_zorgproces <= ?peildatum && ((?eind_zorgproces >= ?peildatum)||(!BOUND(?eind_zorgproces)))) 
36            
37            ?locatie 
38                a onz-g:StationaryArtifact ;
39                onz-g:partOf* ?vestiging_uri .
40            
41            ?vestiging_uri a onz-org:Vestiging ;
42                onz-g:hasLocalizableArea/onz-g:identifiedBy/onz-g:hasPart/onz-g:hasPart ?postcode_6 .
43
44            BIND(IRI(SUBSTR(STR(?postcode_6), 1, STRLEN(STR(?postcode_6)) - 2)) AS ?postcode)
45
46            ?pc_gebied 
47                onz-g:identifiedBy ?postcode ;
48                onz-g:partOf+ ?zk_regio .
49            ?zk_regio a onz-org:ZorgkantoorRegio .
50            ?zorgkantoor onz-g:hasOperatingRange ?zk_regio .
51
52
53            {
54                ?vestiging_uri onz-g:identifiedBy ?vest_nr .
55                ?vest_nr onz-g:hasDataValue ?vestiging .
56                BIND(?vestiging AS ?Organisatieonderdeel)
57            }
58            UNION
59            {
60                ?vestiging_uri onz-org:vestigingVan ?organisatie_uri .
61                BIND("Totaal organisatie" AS ?Organisatieonderdeel)
62            }
63			
64            # Filter indicatie op wlz en datum 
65            ?indicatie
66                a onz-zorg:WlzIndicatie ;
67                onz-g:hasPart/onz-g:isAbout ?sector ;
68                onz-g:hasPart ?lv ;
69                onz-g:isAbout ?client . 
70        	?indicatie onz-g:startDatum ?ind_start .
71        	OPTIONAL { ?indicatie onz-g:eindDatum ?ind_eind }
72        	FILTER (?ind_start <= ?peildatum && ((?ind_eind >= ?peildatum) || (!BOUND(?ind_eind))))
73
74            ?sector
75                a onz-zorg:LangdurigeZorgSector .
76            	FILTER(?sector = onz-zorg:VV)
77            ?lv
78                a onz-zorg:Leveringsvorm .
79
80           	?client a onz-g:Human .
81        }
82}
83GROUP BY ?Organisatieonderdeel
84
85