15.4.2 Hoeveel Wlz-cliënten zijn er per sector?

Concepten

• Langdurige zorg sector
• Mens
• Vestiging
• Vestigingsnummer
• Wlz-indicatie
• ZorgEnVerpleegProces
• Zorgkantoor regio

Relaties

• deel van
• gaat over
• gedefinieerd door
• geïdentificeerd door
• heeft deel
• heeft lokaliseerbaar gebied
• heeft perdurantlocatie
• opereert in regio
• vestiging van

Eigenschappen

• einddatum
• heeft datawaarde
• startdatum

Instanties

• Sector GGZ, B-groep
• Sector GGZ, Wonen
• Sector Lichamelijk gehandicapt
• Sector Licht verstandelijk gehandicapt
• Sector Verpleging en verzorging
• Sector Verstandelijk gehandicapt
• Sector Zintuiglijk gehandicapt, auditief en communicatief
• Sector Zintuiglijk gehandicapt, visueel

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Zorgkantoren 15.4.2
2# Parameters: ?peildatum ?zorgkantoor 
3# Ontologie: versie 2.0.0 of nieuwer
4
5
6PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
7PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
8PREFIX onz-g: <http://purl.org/ozo/onz-g#>
9PREFIX onz-org: <http://purl.org/ozo/onz-org#>
10PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
11PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
12
13SELECT (?vestiging AS ?Indeling)        
14        (COUNT(DISTINCT IF(?sector = onz-zorg:VV, ?client, ?unbound)) AS ?VV)
15        (COUNT(DISTINCT IF(?sector = onz-zorg:LG, ?client, ?unbound)) AS ?LG)
16        (COUNT(DISTINCT IF(?sector = onz-zorg:LVG, ?client, ?unbound)) AS ?LVG)
17        (COUNT(DISTINCT IF(?sector = onz-zorg:VG, ?client, ?unbound)) AS ?VG)
18        (COUNT(DISTINCT IF(?sector = onz-zorg:ZGAUD, ?client, ?unbound)) AS ?ZGAUD)
19        (COUNT(DISTINCT IF(?sector = onz-zorg:ZGVIS, ?client, ?unbound)) AS ?ZGVIS)
20        (COUNT(DISTINCT IF(?sector = onz-zorg:GGZ-B, ?client, ?unbound)) AS ?GGZ_B)
21        (COUNT(DISTINCT IF(?sector = onz-zorg:GGZ-W, ?client, ?unbound)) AS ?GGZ_W)
22 
23
24WHERE
25{
26	# BIND ("2024-01-01"^^xsd:date AS ?peildatum)  # Parameter
27
28    ?sector a onz-zorg:LangdurigeZorgSector .
29    ?client a onz-g:Human .
30    
31    ?indicatie
32        a onz-zorg:WlzIndicatie ;
33        onz-g:isAbout ?client ;
34        onz-g:hasPart/onz-g:isAbout ?sector ;
35        onz-g:startDatum ?start_indicatie .
36        OPTIONAL {?indicatie onz-g:eindDatum ?eind_indicatie}
37        FILTER (?start_indicatie <= ?peildatum && (!BOUND(?eind_indicatie) || ?eind_indicatie >= ?peildatum))
38
39          ?zorgproces a onz-g:CureAndCareProcess ;
40                  onz-g:definedBy ?indicatie ;
41                  onz-g:hasPerdurantLocation/onz-g:partOf* ?locatie ;
42                  onz-g:startDatum ?start_zorgproces .
43      OPTIONAL { ?zorgproces onz-g:eindDatum ?eind_zorgproces }
44      FILTER(?start_zorgproces <= ?peildatum && ( !BOUND(?eind_zorgproces) || ?eind_zorgproces >= ?peildatum ))
45
46
47    # Locatie en vestiging structuur — regio filter applied to all paths
48    ?locatie onz-g:partOf* ?vestiging_uri .
49    ?vestiging_uri a onz-org:Vestiging ;
50        onz-g:hasLocalizableArea/onz-g:identifiedBy/onz-g:hasPart/onz-g:hasPart ?postcode_6 .
51
52    BIND(IRI(SUBSTR(STR(?postcode_6), 1, STRLEN(STR(?postcode_6)) - 2)) AS ?postcode)
53    ?pc_gebied onz-g:identifiedBy ?postcode ;
54        onz-g:partOf+ ?zk_regio .
55    ?zorgkantoor onz-g:hasOperatingRange ?zk_regio .
56    ?zk_regio a onz-org:ZorgkantoorRegio .
57
58    # Vestiging label: per vestiging of totaal organisatie
59    {
60        ?vestiging_uri onz-g:identifiedBy ?vest_nr .
61        ?vest_nr a onz-org:Vestigingsnummer ;
62            onz-g:hasDataValue ?vestiging .
63    } UNION {
64        ?vestiging_uri onz-org:vestigingVan ?organisatie_uri .
65        BIND("Organisatie (gecontracteerd + algemeen)" AS ?vestiging)
66    }
67
68    BIND(IF(BOUND(?zk_regio), STRAFTER(STR(?zk_regio), "/onz-org/"), ?unbound) AS ?zk_regio_code)
69}
70GROUP BY ?vestiging
71ORDER BY ?vestiging
72