12.2 Wat is de verzuimfrequentie (incl. zwangerschapsverlof)?

Concepten

• Arbeidsovereenkomst
• Onverplaatsbaar artefact
• Vestiging
• Vestigingsnummer
• Werkovereenkomst afspraak
• Ziekteperiode
• Zorgkantoor regio
• Zwangerschapsverlof

Relaties

• deel van
• gaat over
• gedefinieerd door
• geïdentificeerd door
• heeft deel
• heeft lokaliseerbaar gebied
• heeft opdrachtnemer
• opereert in regio

Eigenschappen

• einddatum
• heeft datawaarde
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Zorgkantoren 12.2
2# Parameters: ?jaar, ?kwartaal, ?zorgkantoor
3# Ontologie: versie 3.0 of nieuwer
4
5PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
6PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
7PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
8PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
9PREFIX onz-g: <http://purl.org/ozo/onz-g#>
10PREFIX onz-org: <http://purl.org/ozo/onz-org#>
11PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
12
13SELECT 
14    (?vestiging AS ?Indeling)
15    (COUNT(DISTINCT ?persoon) AS ?Aantal_personeelsleden_in_loondienst)
16    (SUM(?meldingen) AS ?Aantal_nieuwe_ziekmeldingen)
17    (SUM(?meldingen) / COUNT(DISTINCT ?persoon) * 100 AS ?Verzuimfrequentie_incl_zwangerschap)
18WHERE {
19        SELECT 
20            ?persoon
21            ?vestiging
22            (COUNT(DISTINCT ?ziekteperiode) AS ?meldingen)
23        WHERE {
24            # BIND(2024 AS ?jaar)
25            # BIND("Q1" AS ?kwartaal)
26            # BIND(onz-org:ZorgkantoorMenzis AS ?zorgkantoor)
27
28            BIND(
29                IF(?kwartaal = 'Q1', xsd:date(CONCAT(STR(?jaar), '-01-01')),
30                IF(?kwartaal = 'Q2', xsd:date(CONCAT(STR(?jaar), '-04-01')),
31                IF(?kwartaal = 'Q3', xsd:date(CONCAT(STR(?jaar), '-07-01')),
32                IF(?kwartaal = 'Q4', xsd:date(CONCAT(STR(?jaar), '-10-01')),
33                '')))) AS ?start_periode)
34            BIND(?start_periode + "P3M"^^xsd:duration + "-P1D"^^xsd:duration AS ?eind_periode)
35
36            ?overeenkomst 
37                a onz-pers:ArbeidsOvereenkomst ; # personeel in loondienst
38                onz-pers:heeftOpdrachtnemer ?persoon ;
39                onz-g:hasPart ?overeenkomst_afspraak .
40
41            ?overeenkomst_afspraak
42                a onz-pers:WerkOvereenkomstAfspraak ;
43                onz-g:startDatum ?start_afspraak .
44            OPTIONAL { ?overeenkomst_afspraak onz-g:eindDatum ?eind_afspraak }
45            FILTER (?start_afspraak <= ?eind_periode && ((!BOUND(?eind_afspraak)) || (?eind_afspraak >= ?start_periode)))
46
47            {   
48            	# Onderdeel per vestiging, OA's met locatie
49            	?overeenkomst_afspraak onz-g:isAbout ?locatie .
50            	?locatie 
51                    a onz-g:StationaryArtifact ;
52                    onz-g:partOf* ?vestiging_uri .
53            
54                ?vestiging_uri 
55                	a onz-org:Vestiging ;
56                    onz-g:hasLocalizableArea/onz-g:identifiedBy/onz-g:hasPart/onz-g:hasPart ?postcode_6 .
57                BIND(IRI(SUBSTR(STR(?postcode_6), 1, STRLEN(STR(?postcode_6)) - 2)) AS ?postcode)
58            
59                ?pc_gebied 
60                    onz-g:identifiedBy ?postcode ;
61                    onz-g:partOf+ ?zk_regio .
62                ?zk_regio a onz-org:ZorgkantoorRegio .
63                ?zorgkantoor onz-g:hasOperatingRange ?zk_regio .
64            
65                ?vestiging_uri onz-g:identifiedBy ?vest_nr .    	
66                ?vest_nr 
67                	a onz-org:Vestigingsnummer ;
68                    onz-g:hasDataValue ?vestiging .
69            } UNION {
70                # Onderdeel Totaal organisatie, inclusief OA's niet gebonden aan een vestiging
71                BIND("Organisatie (gecontracteerd + algemeen)" AS ?vestiging)
72            }
73            
74            # Onderdeel verzuim
75            VALUES ?type_verzuim {
76                onz-pers:ZiektePeriode
77                onz-pers:ZwangerschapsVerlof
78            }
79            OPTIONAL {
80                ?ziekteperiode a ?type_verzuim .
81
82                ?ziekteperiode 
83                    onz-g:definedBy ?overeenkomst ;
84                    onz-g:startDatum ?start_ziekte_periode .
85
86                # Alleen nieuwe ziekmeldingen binnen meetperiode, en binnen de looptijd van de afspraak
87                FILTER(?start_ziekte_periode >= ?start_periode && ?start_ziekte_periode <= ?eind_periode)
88                FILTER(?start_ziekte_periode >= ?start_afspraak && ( !BOUND(?eind_afspraak) || ?start_ziekte_periode <= ?eind_afspraak ))
89            }
90        }
91        GROUP BY ?persoon ?vestiging
92}
93GROUP BY ?vestiging
94ORDER BY ?vestiging
95