15.4.1 Hoeveel mensen met indicaties zijn er per financieringsstroom?

Concepten

• Forensische indicatiestelling
• Indicatiebesluit
• Mens
• Vestiging
• Vestigingsnummer
• Wlz-indicatie
• Wmo-indicatie
• Zorgkantoor regio
• Zvw-indicatie

Relaties

• deel van
• gaat over
• gedefinieerd door
• geïdentificeerd door
• heeft deel
• heeft lokaliseerbaar gebied
• heeft perdurantlocatie
• opereert in regio

Eigenschappen

• einddatum
• heeft datawaarde
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Zorgkantoren 15.4.1
2# Parameters: ?peildatum ?zorgkantoor
3# Ontologie: versie 3.0.0 of nieuwer
4 
5PREFIX onz-g: <http://purl.org/ozo/onz-g#>
6PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
7PREFIX onz-org: <http://purl.org/ozo/onz-org#>
8PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
9PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
10PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
11 
12SELECT 
13	(?vestiging AS ?Indeling)
14    (COUNT(DISTINCT IF(BOUND(?wlz), ?client, ?unbound)) AS ?Wlz)
15    (COUNT(DISTINCT IF(BOUND(?zvw), ?client, ?unbound)) AS ?Zvw)
16    (COUNT(DISTINCT IF(BOUND(?wmo), ?client, ?unbound)) AS ?Wmo)
17    (COUNT(DISTINCT IF(!BOUND(?zvw) && !BOUND(?wlz) && !BOUND(?wmo) , ?client, ?unbound)) AS ?Overig)
18WHERE {
19	# BIND ("2024-01-01"^^xsd:date AS ?peildatum)
20    
21    { 
22        ?indicatie a onz-zorg:IndicatieBesluit 
23    } UNION {
24        ?indicatie a onz-zorg:ForensischeIndicatieStelling
25    }
26    
27    ?indicatie
28    	onz-g:isAbout ?client ;
29        onz-g:startDatum ?start_indicatie .
30        OPTIONAL { ?indicatie onz-g:eindDatum ?eind_indicatie . }
31    FILTER (?start_indicatie <= ?peildatum && (!BOUND(?eind_indicatie) || ?eind_indicatie >= ?peildatum))
32    
33    ?client
34        a onz-g:Human .   
35    
36    OPTIONAL {
37        ?indicatie a onz-zorg:WlzIndicatie .
38        BIND(1 AS ?wlz) .
39     }
40    OPTIONAL {
41        ?indicatie a onz-zorg:ZvwIndicatie .
42        BIND(1 AS ?zvw) .
43    }
44    OPTIONAL {
45        ?indicatie a onz-zorg:WmoIndicatie .
46        BIND(1 AS ?wmo) .
47    }
48
49    {
50        # Per vestiging
51        ?indicatie ^onz-g:definedBy/onz-g:hasPerdurantLocation ?locatie .
52        ?locatie onz-g:partOf* ?vestiging_uri .
53        ?vestiging_uri a onz-org:Vestiging ;
54        onz-g:hasLocalizableArea/onz-g:identifiedBy/onz-g:hasPart/onz-g:hasPart ?postcode_6;
55        onz-g:identifiedBy ?vest_nr . 
56        BIND(IRI(SUBSTR(STR(?postcode_6), 1, STRLEN(STR(?postcode_6)) - 2)) AS ?postcode)
57        ?pc_gebied 
58            onz-g:identifiedBy ?postcode ;
59        onz-g:partOf+ ?zk_regio .
60        ?zk_regio a onz-org:ZorgkantoorRegio .
61        ?zorgkantoor onz-g:hasOperatingRange ?zk_regio .
62        ?vest_nr a onz-org:Vestigingsnummer ;
63        onz-g:hasDataValue ?vestiging .
64    } UNION {
65        # Totaal organisatie (inclusief zorgprocessen zonder locatie)
66        BIND("Organisatie (gecontracteerd + algemeen)" AS ?vestiging)
67    }
68}
69GROUP BY ?vestiging
70ORDER BY ?vestiging
71