9.1 Wat is het aantal vrijwilligers?

Concepten

• Onverplaatsbaar artefact
• Vestiging
• Vestigingsnummer
• Vrijwilligersovereenkomst
• Werkovereenkomst afspraak
• Zorgkantoor regio

Relaties

• deel van
• gaat over
• geïdentificeerd door
• heeft deel
• heeft lokaliseerbaar gebied
• heeft opdrachtnemer
• opereert in regio

Eigenschappen

• einddatum
• heeft datawaarde
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Zorgkantoren 9.1
2# Parameters: ?jaar, ?kwartaal, ?zorgkantoor
3# Ontologie: versie 3.0 of nieuwer
4
5PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
6PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
7PREFIX onz-g: <http://purl.org/ozo/onz-g#>
8PREFIX onz-org: <http://purl.org/ozo/onz-org#>
9PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
10
11SELECT 
12    (?vestiging AS ?Indeling)
13    (COUNT (DISTINCT ?persoon) AS ?Aantal_vrijwilligers)
14
15{
16    # BIND(2024 AS ?jaar)
17    # BIND("Q1" AS ?kwartaal)
18    # BIND(onz-org:ZorgkantoorMenzis AS ?zorgkantoor)
19    BIND(IF(?kwartaal = 'Q1', xsd:date(CONCAT(STR(?jaar), '-01-01')),
20        IF(?kwartaal = 'Q2', xsd:date(CONCAT(STR(?jaar), '-04-01')),
21        IF(?kwartaal = 'Q3', xsd:date(CONCAT(STR(?jaar), '-07-01')),
22        IF(?kwartaal = 'Q4', xsd:date(CONCAT(STR(?jaar), '-10-01')),
23        '')))) AS ?start_periode)
24    BIND(?start_periode + "P3M"^^xsd:duration + "-P1D"^^xsd:duration AS ?eind_periode)
25    
26    ?overeenkomst 
27        a onz-pers:VrijwilligersOvereenkomst ;
28        onz-pers:heeftOpdrachtnemer ?persoon ;
29        onz-g:hasPart ?overeenkomst_afspraak .
30    ?overeenkomst_afspraak
31        a onz-pers:WerkOvereenkomstAfspraak ;
32        onz-g:startDatum ?start_afspraak .
33    OPTIONAL { ?overeenkomst_afspraak onz-g:eindDatum ?eind_afspraak }
34    FILTER(?start_afspraak <= ?eind_periode && ((?eind_afspraak >= ?start_periode) || (!BOUND(?eind_afspraak))))
35    
36    {     
37        ?overeenkomst_afspraak onz-g:isAbout ?locatie .
38        ?locatie a onz-g:StationaryArtifact ;
39        onz-g:partOf* ?vestiging_uri .
40    	?vestiging_uri a onz-org:Vestiging ;
41        onz-g:hasLocalizableArea/onz-g:identifiedBy/onz-g:hasPart/onz-g:hasPart ?postcode_6 .
42    	BIND(IRI(SUBSTR(STR(?postcode_6), 1, STRLEN(STR(?postcode_6)) - 2)) AS ?postcode)
43        ?pc_gebied 
44            onz-g:identifiedBy ?postcode ;
45            onz-g:partOf+ ?zk_regio .
46        ?zk_regio a onz-org:ZorgkantoorRegio .
47        ?zorgkantoor onz-g:hasOperatingRange ?zk_regio .
48            ?vestiging_uri onz-g:identifiedBy ?vest_nr .    	
49            ?vest_nr a onz-org:Vestigingsnummer ;
50                onz-g:hasDataValue ?vestiging .
51    } UNION {
52        # Includeer ook de organisatie als geheel en label deze als vestiging
53        BIND("Organisatie (gecontracteerd + algemeen)" AS ?vestiging)
54    }
55}
56GROUP BY ?vestiging 
57ORDER BY ?vestiging 
58