4.1 Wat is de gemiddelde contractomvang personeel op een peildatum?

Concepten

• Arbeidsovereenkomst
• Contractomvangwaarde
• Functie in organisatie-rol
• Onverplaatsbaar artefact
• Vestiging
• Vestigingsnummer
• Werkovereenkomst afspraak
• Zorgkantoor regio
• Zorgverlener (functie)

Relaties

• deel van
• gaat over
• geïdentificeerd door
• heeft deel
• heeft lokaliseerbaar gebied
• heeft meeteenheid
• heeft opdrachtnemer
• opereert in regio

Eigenschappen

• einddatum
• heeft datawaarde
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Zorgkantoren 4.1 
2# Parameters: ?peildatum, ?zorgkantoor
3# Ontologie: versie 3.0 of nieuwer
4
5PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
6PREFIX onz-g: <http://purl.org/ozo/onz-g#>
7PREFIX time: <http://www.w3.org/2006/time#>
8PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
9PREFIX onz-org: <http://purl.org/ozo/onz-org#>
10
11SELECT
12    (?vestiging AS ?Indeling)
13	(IF(COUNT(DISTINCT ?zorg_persoon)=0, "Ongedefineerd", SUM(?teller_waarde * ?zorg)/COUNT(DISTINCT ?zorg_persoon)) AS ?Gem_contracturen_per_zorgverlener)
14	(IF(COUNT(DISTINCT ?niet_zorg_persoon)=0, "Ongedefineerd", SUM(?teller_waarde * ?niet_zorg)/COUNT(DISTINCT ?niet_zorg_persoon)) AS ?Gem_contracturen_per_niet_zorgverlener)
15
16{
17
18    # BIND(onz-org:ZorgkantoorMenzis AS ?zorgkantoor)
19    # BIND ("2024-01-01"^^xsd:date AS ?peildatum)
20
21    ?overeenkomst 
22        a onz-pers:ArbeidsOvereenkomst ;
23        onz-pers:heeftOpdrachtnemer ?persoon ;
24        onz-g:hasPart ?overeenkomst_afspraak .
25    ?overeenkomst_afspraak
26        a onz-pers:WerkOvereenkomstAfspraak ;
27        onz-g:startDatum ?start_afspraak .
28    OPTIONAL {
29        ?overeenkomst_afspraak onz-g:eindDatum ?eind_afspraak
30    }
31    FILTER (?start_afspraak <= ?peildatum && (?eind_afspraak >= ?peildatum || !BOUND(?eind_afspraak)))
32
33    # Bepaal de omvang van het contract in uren per week
34    ?overeenkomst_afspraak onz-g:hasPart/onz-g:isAbout ?contract_omvang .
35    ?contract_omvang
36        a onz-pers:ContractOmvangWaarde ;
37        onz-g:hasDataValue ?omvang_waarde ;
38        onz-g:hasUnitOfMeasure ?omvang_eenheid .
39    ?omvang_eenheid onz-g:hasDataValue ?omvang_correctie .
40    BIND(?omvang_waarde*?omvang_correctie AS ?teller_waarde)
41    
42    {   
43        # bepaal vestiging en zorgkantoor regio voor iedere contractafspraak
44        ?overeenkomst_afspraak onz-g:isAbout ?locatie .
45        ?locatie 
46            a onz-g:StationaryArtifact ;
47            onz-g:partOf* ?vestiging_uri .
48        ?vestiging_uri a onz-org:Vestiging ;
49            onz-g:hasLocalizableArea/onz-g:identifiedBy/onz-g:hasPart/onz-g:hasPart ?postcode_6 .
50        BIND(IRI(SUBSTR(STR(?postcode_6), 1, STRLEN(STR(?postcode_6)) - 2)) AS ?postcode)
51        ?pc_gebied 
52            onz-g:identifiedBy ?postcode ;
53            onz-g:partOf+ ?zk_regio .
54        ?zk_regio a onz-org:ZorgkantoorRegio .
55        ?zorgkantoor onz-g:hasOperatingRange ?zk_regio .
56        ?vestiging_uri onz-g:identifiedBy ?vest_nr .    	
57        ?vest_nr a onz-org:Vestigingsnummer ;
58            onz-g:hasDataValue ?vestiging .
59    } 
60    UNION {
61        # Includeer ook de organisatie als geheel en label deze als vestiging
62        BIND("Organisatie (gecontracteerd + algemeen)" AS ?vestiging)
63    }
64
65    # Bepaal of de functie op de overeenkomst van het type ZorgverlenerFunctie is
66    ?overeenkomst_afspraak onz-g:isAbout ?functie .
67    ?functie a onz-g:OccupationalPositionRole .
68    BIND(IF (EXISTS {?functie a onz-pers:ZorgverlenerFunctie}, 1, 0) AS ?zorg)
69    BIND(IF (?zorg = 0, 1, 0) AS ?niet_zorg)
70    BIND(IF(?zorg = 1, ?persoon, ?unbound) AS ?zorg_persoon)
71    BIND(IF(?niet_zorg = 1, ?persoon, ?unbound) AS ?niet_zorg_persoon)
72} 
73GROUP BY ?vestiging
74