1.1.2 Wat is het aantal cliënten met een Wlz-indicatie per (combinatie van) leveringsvorm(en) per zorgprofiel?

Concepten

• Leveringsvorm
• Mens
• Verpleegproces
• Vestiging
• Vestigingsnummer
• Wlz-indicatie
• Zorgprofiel

Relaties

• deel van
• gaat over
• geïdentificeerd door
• heeft deel
• heeft perdurantlocatie

Eigenschappen

• einddatum
• heeft datawaarde
• indicatie behandeling
• startdatum

Instanties

• Modulair pakket thuis
• Persoonsgebonden budget
• Verblijf in een instelling
• Volledig pakket thuis

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: IGJ 1.1.2
2# Parameters: ?vestigingsnummer, ?peildatum
3# Ontologie: versie 3.0.0
4
5PREFIX onz-g: <http://purl.org/ozo/onz-g#>
6PREFIX onz-org: <http://purl.org/ozo/onz-org#>
7PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
8PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
9PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
10
11SELECT 
12    ?zorgprofiel
13    (SUM(?max_verblijf_met_behandeling) AS ?verblijf_met_behandeling)
14    (SUM(?max_verblijf_zonder_behandeling) AS ?verblijf_zonder_behandeling)
15    (SUM(?max_pgb) AS ?pgb)
16    (SUM(?max_mpt) AS ?mpt)	
17    (SUM(?max_vpt) AS ?vpt)
18    (SUM(?is_pgb_en_mpt) AS ?pgb_en_mpt)
19    (COUNT(DISTINCT ?client) AS ?aantal_uniek)
20{
21    {
22        SELECT 
23            ?client
24            ?zorgprofiel
25            (MAX(?is_verblijf_met_behandeling) AS ?max_verblijf_met_behandeling)
26            (MAX(?is_verblijf_zonder_behandeling) AS ?max_verblijf_zonder_behandeling)
27            (MAX(?is_pgb) AS ?max_pgb)
28            (MAX(?is_mpt) AS ?max_mpt)	
29            (MAX(?is_vpt) AS ?max_vpt)
30        {
31#            BIND($(vestigingsnummer) AS ?vestigingsnummer)
32#            BIND($(peildatum) AS ?peildatum)
33# Oude vestigingsnummer triple
34#            ?vestiging
35#                a onz-org:Vestiging ;
36#                onz-g:identifiedBy/onz-g:hasDataValue ?vestigingsnummer .
37
38# Nieuwe vestigingsnummer triple
39            ?vestiging 
40                a onz-org:Vestiging ;
41                onz-g:identifiedBy ?vestigingsnummer_object .
42            ?vestigingsnummer_object
43                a onz-org:Vestigingsnummer ;
44                onz-g:hasDataValue ?vestigingsnummer .
45            ?leveringsvorm
46                a onz-zorg:Leveringsvorm .
47            ?zorgprofiel
48                    a onz-zorg:ZorgProfiel .
49
50            ?client
51                a onz-g:Human .
52            ?indicatie 
53                a onz-zorg:WlzIndicatie ;
54                onz-g:startDatum ?start_indicatie ;
55                onz-zorg:heeftIndicatieBehandeling ?behandeling ;
56                onz-g:isAbout ?client ;
57                onz-g:isAbout ?zorgproces ;
58                onz-g:hasPart ?leveringsvorm ;
59                onz-g:hasPart ?zorgprofiel .
60            OPTIONAL {?indicatie onz-g:eindDatum ?eind_indicatie}
61            FILTER(?peildatum >= ?start_indicatie && (?peildatum <= ?eind_indicatie || !BOUND(?eind_indicatie)))
62                
63            ?zorgproces
64                a onz-zorg:NursingProcess ;
65                onz-g:startDatum ?start_zorgproces ;
66                onz-g:hasPerdurantLocation/onz-g:partOf* ?vestiging ;
67                OPTIONAL {?zorgproces onz-g:eindDatum ?eind_zorgproces}
68            FILTER(?peildatum >= ?start_zorgproces && (?peildatum <= ?eind_zorgproces || !BOUND(?eind_zorgproces)))
69            BIND(IF(?leveringsvorm = onz-zorg:instelling && ?behandeling, 1, 0) AS ?is_verblijf_met_behandeling)
70            BIND(IF(?leveringsvorm = onz-zorg:instelling && !?behandeling, 1, 0) AS ?is_verblijf_zonder_behandeling)
71            BIND(IF(?leveringsvorm = onz-zorg:pgb, 1, 0) AS ?is_pgb)
72            BIND(IF(?leveringsvorm = onz-zorg:mpt, 1, 0) AS ?is_mpt)
73            BIND(IF(?leveringsvorm = onz-zorg:vpt, 1, 0) AS ?is_vpt)
74            
75        } 
76        GROUP BY ?client ?zorgprofiel
77    }
78    BIND(IF(?max_pgb = 1 && ?max_mpt = 1, 1, 0) AS ?is_pgb_en_mpt)
79}
80GROUP BY ?zorgprofiel
81