1.2.1. Wat is het aantal medewerkers (en het percentage t.o.v. totaal) met een zorgverlener functie per kwalificatieniveau per soort werkovereenkomst?

Concepten

• Arbeidsovereenkomst
• Arbeidsovereenkomst bepaalde tijd
• Arbeidsovereenkomst beroeps begeleidende leerweg
• Arbeidsovereenkomst onbepaalde tijd
• Inhuurovereenkomst
• ODB Kwalificatiewaarde
• Onverplaatsbaar artefact
• Oproepovereenkomst
• Stage-overeenkomst
• Uitzendovereenkomst
• Vestiging
• Vestigingsnummer
• Vrijwilligersovereenkomst
• Werkovereenkomst
• Werkovereenkomst afspraak
• Zorgverlener (functie)

Relaties

• deel van
• gaat over
• geïdentificeerd door
• heeft deel
• heeft eigenschap of kenmerk
• heeft eigenschapswaarde
• heeft opdrachtnemer

Eigenschappen

• einddatum
• heeft datawaarde
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: IGJ 1.2.1
2# Parameters: ?vestigingsnummer, ?peildatum
3# Ontologie: versie 3.0.0
4
5PREFIX onz-org: <http://purl.org/ozo/onz-org#>
6PREFIX onz-g: <http://purl.org/ozo/onz-g#>
7PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
8PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
9PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
10
11SELECT
12    ?kwalificatie_niveau
13    (SUM(?onbepaald) AS ?Aantal_medewerkers_met_een_werkovereenkomst_voor_onbepaalde_tijd_met_een_zorgverlener_functie) 
14    (SUM(?bepaald) AS ?Aantal_medewerkers_met_een_werkovereenkomst_voor_bepaalde_tijd_met_een_zorgverlener_functie)
15    (SUM(?oproep) AS ?Aantal_medewerkers_met_een_oproepovereenkomst_met_een_zorgverlener_functie)
16    (SUM(?bbl) AS ?Aantal_medewerkers_met_een_werkovereenkomst_BBL_met_een_zorgverlener_functie)
17    (SUM(?inhuur) AS ?Aantal_medewerkers_met_een_inhuurovereenkomst_met_een_zorgverlener_functie)
18    (SUM(?uitzend) AS ?Aantal_medewerkers_met_een_uitzendovereenkomst_met_een_zorgverlener_functie)
19    (SUM(?stage) AS ?Aantal_medewerkers_met_een_stageovereenkomst_met_een_zorgverlener_functie)
20    (SUM(?vrijwilliger) AS ?Aantal_medewerkers_met_een_vrijwilligersovereenkomst_met_een_zorgverlener_functie)
21    (SUM(?alle_soorten_ok) AS ?Totaal)
22{
23    SELECT DISTINCT
24		?type_overeenkomst
25		?persoon
26		?kwalificatie_niveau
27        ?onbepaald ?bepaald ?oproep ?bbl ?inhuur ?uitzend ?stage ?vrijwilliger
28        ?alle_soorten_ok
29    {
30        # BIND("2024-06-12"^^xsd:date AS ?peildatum)
31		?type_overeenkomst
32        	rdfs:subClassOf onz-pers:WerkOvereenkomst .
33    	FILTER(?type_overeenkomst != onz-pers:ArbeidsOvereenkomst && ?type_overeenkomst != onz-pers:WerkOvereenkomst)
34        ?overeenkomst 
35            a ?type_overeenkomst ;
36            onz-pers:heeftOpdrachtnemer ?persoon ;
37            onz-g:hasPart ?overeenkomst_afspraak .
38        ?overeenkomst_afspraak
39            a onz-pers:WerkOvereenkomstAfspraak ;
40            onz-g:startDatum ?start_afspraak .
41        OPTIONAL {
42            ?overeenkomst_afspraak onz-g:eindDatum ?eind_afspraak
43        }
44        FILTER(?start_afspraak <= ?peildatum && (?eind_afspraak >= ?peildatum || !BOUND(?eind_afspraak)))
45        ?overeenkomst_afspraak onz-g:isAbout ?functie .                
46        ?functie 
47        	a onz-pers:ZorgverlenerFunctie ;
48     		onz-g:hasQuality /onz-g:hasQualityValue ?functie_niveau .
49    	{
50            ?functie_niveau
51                a onz-pers:ODBKwalificatieWaarde ;
52                rdfs:label ?kwalificatie_niveau .
53        } UNION {
54            BIND("Totaal aantal medewerkers" AS ?kwalificatie_niveau)
55        }
56        ?overeenkomst_afspraak onz-g:isAbout ?locatie .
57        ?locatie a onz-g:StationaryArtifact .
58        ?locatie onz-g:partOf* ?vestiging_uri .   
59        ?vestiging_uri
60        	a onz-org:Vestiging ;
61            onz-g:identifiedBy ?vestigingsnummer_object .
62        ?vestigingsnummer_object
63        	a onz-org:Vestigingsnummer ;
64        	onz-g:hasDataValue ?vestigingsnummer .
65    
66        BIND(IF (?type_overeenkomst = onz-pers:ArbeidsOvereenkomstOnbepaaldeTijd, 1, 0) AS ?onbepaald)
67        BIND(IF (?type_overeenkomst = onz-pers:ArbeidsOvereenkomstBepaaldeTijd, 1, 0) AS ?bepaald)
68        BIND(IF (?type_overeenkomst = onz-pers:OproepOvereenkomst, 1, 0) AS ?oproep)
69        BIND(IF (?type_overeenkomst = onz-pers:ArbeidsOvereenkomstBBL, 1, 0) AS ?bbl)
70        BIND(IF (?type_overeenkomst = onz-pers:InhuurOvereenkomst, 1, 0) AS ?inhuur)
71        BIND(IF (?type_overeenkomst = onz-pers:UitzendOvereenkomst, 1, 0) AS ?uitzend)
72        BIND(IF (?type_overeenkomst = onz-pers:StageOvereenkomst, 1, 0) AS ?stage)
73        BIND(IF (?type_overeenkomst = onz-pers:VrijwilligersOvereenkomst, 1, 0) AS ?vrijwilliger)
74        BIND(1 AS ?alle_soorten_ok)
75    } 
76}
77GROUP BY ?kwalificatie_niveau
78ORDER BY ?kwalificatie_niveau
79