1.2.3. Wat is het aantal ingezette uren (en het percentage t.o.v. totaal) aan medewerkers met een zorgverlener functie per kwalificatieniveau per soort werkovereenkomst?

Concepten

• Arbeidsovereenkomst bepaalde tijd
• Arbeidsovereenkomst beroeps begeleidende leerweg
• Arbeidsovereenkomst onbepaalde tijd
• Gewerkte periode
• Gewerkte tijd
• Inhuurovereenkomst
• ODB Kwalificatiewaarde
• Oproepovereenkomst
• Stage-overeenkomst
• Uitzendovereenkomst
• Vestiging
• Vestigingsnummer
• Vrijwilligersovereenkomst
• Zorgverlener (functie)

Relaties

• deel van
• gaat over
• gedefinieerd door
• geïdentificeerd door
• heeft deel
• heeft eigenschap of kenmerk
• heeft eigenschapswaarde
• heeft opdrachtnemer
• heeft perdurantlocatie

Eigenschappen

• einddatum
• heeft datawaarde
• heeftBeginTijd
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: IGJ 1.2.3
2# Parameters: ?peildatum, ?vestigingsnummer
3# Ontologie: versie 3.0.0 of nieuwer
4
5PREFIX onz-org: <http://purl.org/ozo/onz-org#>
6PREFIX onz-g: <http://purl.org/ozo/onz-g#>
7PREFIX onz-pers: <http://purl.org/ozo/onz-pers#> 
8PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
9PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
10
11SELECT
12    ?kwalificatie_niveau
13    (SUM(?onbepaald) AS ?Aantal_ingezette_uren_mbt_werkovereenkomsten_voor_onbepaalde_tijd_met_een_zorgverlener_functie) 
14    (SUM(?bepaald) AS ?Aantal_ingezette_uren_mbt_werkovereenkomsten_voor_bepaalde_tijd_met_een_zorgverlener_functie)
15    (SUM(?oproep) AS ?Aantal_ingezette_uren_mbt_oproepovereenkomsten_met_een_zorgverlener_functie)
16    (SUM(?bbl) AS ?Aantal_ingezette_uren_mbt_werkovereenkomsten_BBL_met_een_zorgverlener_functie)
17    (SUM(?inhuur) AS ?Aantal_ingezette_uren_mbt_inhuurovereenkomsten_met_een_zorgverlener_functie)
18    (SUM(?uitzend) AS ?Aantal_ingezette_uren_mbt_uitzendovereenkomsten_met_een_zorgverlener_functie)
19    (SUM(?stage) AS ?Aantal_ingezette_uren_mbt_stageovereenkomsten_met_een_zorgverlener_functie)
20    (SUM(?vrijwilliger) AS ?Aantal_ingezette_uren_mbt_vrijwilligersovereenkomsten_met_een_zorgverlener_functie)
21    (SUM(?alle_soorten_ok) AS ?Totaal_aantal_ingezette_uren)
22{
23    SELECT DISTINCT
24        ?medewerker
25        ?kwalificatie_niveau
26        ?onbepaald ?bepaald ?oproep ?bbl ?inhuur ?uitzend ?stage ?vrijwilliger
27        ?alle_soorten_ok
28    {      
29        # BIND("2023-05-29"^^xsd:date AS ?peildatum)
30        # BIND(?vestigingsnummer AS ?vestigingsnummer)
31        
32        VALUES ?type_overeenkomst {
33            onz-pers:ArbeidsOvereenkomstOnbepaaldeTijd
34            onz-pers:ArbeidsOvereenkomstBepaaldeTijd
35            onz-pers:OproepOvereenkomst
36            onz-pers:ArbeidsOvereenkomstBBL
37            onz-pers:InhuurOvereenkomst
38            onz-pers:UitzendOvereenkomst
39            onz-pers:StageOvereenkomst
40            onz-pers:VrijwilligersOvereenkomst
41        }
42        ?overeenkomst 
43            a ?type_overeenkomst ;
44            onz-pers:heeftOpdrachtnemer ?medewerker ;
45            onz-g:hasPart ?afspraak .
46        ?afspraak
47            onz-g:isAbout ?functie ;
48            onz-g:startDatum ?start_afspraak .
49        OPTIONAL {?afspraak onz-g:eindDatum ?eind_afspraak}
50        ?functie
51            a onz-pers:ZorgverlenerFunctie ;
52            onz-g:hasQuality /onz-g:hasQualityValue ?functie_niveau .
53        FILTER (?start_afspraak <= ?peildatum && (!BOUND(?eind_afspraak) || ?eind_afspraak >= ?peildatum))
54        ?functie_niveau
55            a onz-pers:ODBKwalificatieWaarde .
56        {
57            ?functie_niveau
58                a onz-pers:ODBKwalificatieWaarde ;
59                rdfs:label ?kwalificatie_niveau .
60        } UNION {
61            BIND("Totaal aantal ingezette uren" AS ?kwalificatie_niveau ) 
62        }
63        
64        # Werkperiode van alle zorgverlener functies
65        ?inzet
66            a onz-pers:GewerktePeriode ;
67            onz-g:definedBy ?overeenkomst ;
68            onz-g:hasPerdurantLocation ?werk_locatie ;
69            onz-g:hasBeginTimeStamp ?start_werk ;
70            onz-g:hasQuality ?gewerkte_tijd .
71            
72        ?werk_locatie onz-g:partOf* ?vestiging . # vind Vestiging die hoort bij werk_locatie
73        ?vestiging 
74            a onz-org:Vestiging ;
75            onz-g:identifiedBy ?vestigingsnummer_object .
76        ?vestigingsnummer_object
77            a onz-org:Vestigingsnummer ;
78            onz-g:hasDataValue ?vestigingsnummer . # filter vestiging op gegeven vestigingsnummer
79        
80        ?gewerkte_tijd
81            a onz-pers:GewerkteTijd ;
82            onz-g:hasQualityValue/onz-g:hasDataValue ?inzet_uren .
83        
84        BIND(STRDT(SUBSTR(STR(?start_werk), 1, 10), xsd:date) AS ?start_werk_datum)
85        FILTER(?start_werk_datum = ?peildatum )
86        
87        BIND(IF (?type_overeenkomst = onz-pers:ArbeidsOvereenkomstOnbepaaldeTijd, ?inzet_uren, 0) AS ?onbepaald)
88        BIND(IF (?type_overeenkomst = onz-pers:ArbeidsOvereenkomstBepaaldeTijd, ?inzet_uren, 0) AS ?bepaald)
89        BIND(IF (?type_overeenkomst = onz-pers:OproepOvereenkomst, ?inzet_uren, 0) AS ?oproep)
90        BIND(IF (?type_overeenkomst = onz-pers:ArbeidsOvereenkomstBBL, ?inzet_uren, 0) AS ?bbl)
91        BIND(IF (?type_overeenkomst = onz-pers:InhuurOvereenkomst, ?inzet_uren, 0) AS ?inhuur)
92        BIND(IF (?type_overeenkomst = onz-pers:UitzendOvereenkomst, ?inzet_uren, 0) AS ?uitzend)
93        BIND(IF (?type_overeenkomst = onz-pers:StageOvereenkomst, ?inzet_uren, 0) AS ?stage)
94        BIND(IF (?type_overeenkomst = onz-pers:VrijwilligersOvereenkomst, ?inzet_uren, 0) AS ?vrijwilliger)
95        BIND(?inzet_uren AS ?alle_soorten_ok)
96    } 
97}
98GROUP BY ?kwalificatie_niveau
99ORDER BY ?kwalificatie_niveau
100