1. Wat zijn de kosten van voeding?

Concepten

• Grootboekpost
• Grootboekrekening
• Grootboekrubriek

Relaties

• deel van

Eigenschappen

• heeft datum
• heeftGeldBedrag

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1PREFIX onz-g: <http://purl.org/ozo/onz-g#>
2PREFIX onz-fin: <http://purl.org/ozo/onz-fin#>
3PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
4
5# Indicator: Nza Kostprijs 1
6# Canonical id: MONO-0012 - "Wat zijn de kosten van voeding?"
7# Parameters: ?meetperiode
8# Ontologie: versie 3.0.0 of nieuwer
9# Vereist uitgebreide financiele dataset en RGS-zorg versie om te testen
10
11SELECT
12("Totaal organisatie" AS ?Indeling)
13("Totaal jaar" AS ?Periode)
14(ROUND(SUM(?geld_bedrag_post) * 100) / 100 AS ?Bedrag)
15WHERE {
16
17    BIND("2025-01-01"^^xsd:date AS ?startperiode)
18    BIND("2025-12-31"^^xsd:date AS ?eindperiode)
19
20    ?grootboekpost
21    a onz-fin:Grootboekpost ;
22    onz-fin:heeftGeldBedrag ?geld_bedrag_post ;
23    onz-g:hasDate ?boekingsdatum ;
24    onz-g:partOf ?rubriek .
25
26    # Behoud de grootboekpost alleen voor de meest specifieke rubriek,
27    # om eventuele dubbeltelling door de hiërarchische structuur rubriekcodes te voorkomen
28    FILTER NOT EXISTS {
29        ?grootboekpost onz-g:partOf ?specifiekereRubriek .
30        ?specifiekereRubriek onz-g:partOf+ ?rubriek .
31    }
32
33    FILTER(?boekingsdatum >= ?startperiode && ?boekingsdatum <= ?eindperiode)
34
35    # Vind de juiste rubrieken voor Prismant en RGS
36    {
37
38        VALUES ?rubriekType { onz-fin:Grootboekrubriek onz-fin:Grootboekrekening }
39        ?rubriek a ?rubriekType .
40        BIND(STRAFTER(STR(?rubriek), STR(onz-fin:)) AS ?rubriekCode)
41        VALUES (?mappingPrefix ?kostenSoort) {
42            ("4310" "Kosten van voeding")
43            ("4311" "Kosten van voeding")
44            ("4312" "Kosten van voeding")
45            ("4313" "Kosten van voeding")
46            ("4320" "Kosten van voeding")
47            ("4330" "Kosten van voeding")
48        }
49
50        # filter startswith specifiek voor prismant
51        FILTER(STRSTARTS(?rubriekCode, ?mappingPrefix))
52
53    }
54    UNION
55    {
56
57        VALUES ?rubriekType { onz-fin:Grootboekrubriek onz-fin:Grootboekrekening }
58        ?rubriek a ?rubriekType .
59        BIND(STRAFTER(STR(?rubriek), STR(onz-fin:)) AS ?rubriekCode)
60        VALUES (?rubriekCode ?kostenSoort) {
61            ("WKprKvgKvv" "Kosten van voeding")
62        }
63
64    }
65
66}
67