1.1. Welke zorgprofielen kunnen geleverd worden bij leveringsvorm Verblijf?

Concepten

• Vestiging
• Wlz-indicatie

Relaties

• gedefinieerd door
• heeft deel
• heeft perdurantlocatie

Eigenschappen

• einddatum
• startdatum

Instanties

• LG Wonen met begeleiding en enige verzorging
• LG Wonen met begeleiding en enige verzorging, ook begeleiding groep
• LG Wonen met enige begeleiding en enige verzorging (2015)
• LG Wonen met enige begeleiding en enige verzorging (2015), ook begeleiding groep
• LG Wonen met enige begeleiding en verzorging (2015)
• LG Wonen met enige begeleiding en verzorging (2015), ook begeleiding groep
• VV Beschermd wonen met intensieve dementiezorg
• VV Beschermd wonen met intensieve verzorging en verpleging
• VV Beschermd wonen met zeer intensieve zorg, vanwege specifieke aandoeningen, met de nadruk op begeleiding
• VV Beschermd wonen met zeer intensieve zorg, vanwege specifieke aandoeningen, met de nadruk op verzorging en verpleging
• VV Beschut wonen met intensieve begeleiding en uitgebreide verzorging
• VV Herstelgerichte behandeling met verpleging en verzorging
• Verblijf in een instelling

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Zorgkantoren Clientinformatie - Indicaties per Vestiging per Kwartaal
2# Parameters: ?start_meetperiode, ?eind_meetperiode
3# Ontologie: v3
4 
5PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
6PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
7PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
8PREFIX onz-g: <http://purl.org/ozo/onz-g#>
9PREFIX onz-org: <http://purl.org/ozo/onz-org#>
10 
11SELECT ?kwartaal ?vestiging_naam (GROUP_CONCAT(DISTINCT ?profiel_naam_kort; SEPARATOR=", ") AS ?geleverde_zorgprofielen)
12WHERE {
13  {
14    SELECT ?kwartaal ?vestiging_naam ?profiel_naam_kort
15    WHERE {
16   	  # kwartalen
17      VALUES (?kwartaal ?kwartaal_start ?kwartaal_eind) {
18        ("Q1-2024" "2024-01-01"^^xsd:date "2024-03-31"^^xsd:date)
19        ("Q2-2024" "2024-04-01"^^xsd:date "2024-06-30"^^xsd:date)
20        ("Q3-2024" "2024-07-01"^^xsd:date "2024-09-30"^^xsd:date)
21        ("Q4-2024" "2024-10-01"^^xsd:date "2024-12-31"^^xsd:date)
22      }
23     
24      # Zorgprofielen VV-4 t/m VV-9b en LG-1 t/m LG-3
25      VALUES ?profiel {
26        onz-zorg:4VV
27        onz-zorg:5VV
28        onz-zorg:6VV
29        onz-zorg:7VV
30        onz-zorg:8VV
31        onz-zorg:9BVV
32        onz-zorg:1LG
33        onz-zorg:1LG-G
34        onz-zorg:2LG
35        onz-zorg:2LG-G
36        onz-zorg:3LG
37        onz-zorg:3LG-G
38      }
39      BIND(STRAFTER(STR(?profiel), '#') AS ?profiel_naam_kort)
40     
41      # Selectie Indicaties
42      ?indicatie a onz-zorg:WlzIndicatie ;
43                onz-g:hasPart ?profiel ;
44                onz-g:hasPart onz-zorg:instelling ;
45                onz-g:startDatum ?start_datum_ind .
46      OPTIONAL { ?indicatie onz-g:eindDatum ?eind_datum_ind . }
47     
48      # Indicatie moet minimaal 1 dag overlappen met het betreffende kwartaal
49      FILTER (?start_datum_ind <= ?kwartaal_eind && (!BOUND(?eind_datum_ind) || ?eind_datum_ind >= ?kwartaal_start))
50     
51      # Koppeling aan Zorgproces en Vestiging
52      ?zorgproces onz-g:definedBy ?indicatie .
53      ?zorgproces onz-g:hasPerdurantLocation ?vestiging .
54      ?vestiging a onz-org:Vestiging ;
55                 rdfs:label ?vestiging_naam .
56    }
57    ORDER BY ?kwartaal ?vestiging_naam ?profiel_naam_kort
58  }
59}
60# Groepering en Sortering
61GROUP BY ?kwartaal ?vestiging_naam
62ORDER BY ?kwartaal ?vestiging_naam