1.5.2 Aantal wooneenheden per huurprijscategorie

Concepten

• Bedrijf
• HuurBedrag
• Vestiging
• Vestigingsnummer
• Wooneenheid

Relaties

• deel van
• geïdentificeerd door
• heeft eigenschap of kenmerk
• heeft eigenschapswaarde
• heeftToegekendeFinanciëleEntiteit
• vestiging van

Eigenschappen

• heeft datawaarde

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Zorgkantoren Clientinformatie 1.5.2
2# Parameters: -
3# Ontologie: versie 2.2.0 of nieuwer
4
5PREFIX onz-org: <http://purl.org/ozo/onz-org#>
6PREFIX onz-g: <http://purl.org/ozo/onz-g#>
7PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
8PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
9PREFIX onz-fin: <http://purl.org/ozo/onz-fin#>
10
11SELECT  ?vestiging 
12        (SUM(?tot_800) AS ?aantal_tot_800)
13		(SUM(?800_1200) AS ?aantal_800_1200)
14		(SUM(?1200_2000) AS ?aantal_1200_2000)
15		(SUM(?vanaf_2000) AS ?aantal_vanaf_2000)
16WHERE 
17{ 
18    SELECT  ?vestiging ?wooneenheid
19            (SUM(?sum_financialValue) AS ?totaal)
20            (IF(?totaal<"800"^^xsd:float,1, 0) AS ?tot_800)
21			(IF((?totaal>="800"^^xsd:float) && (?totaal<"1200"^^xsd:float),1, 0) AS ?800_1200)
22			(IF((?totaal>="1200"^^xsd:float) && (?totaal<"2000"^^xsd:float),1, 0) AS ?1200_2000)
23			(IF(?totaal>="2000"^^xsd:float,1, 0) AS ?vanaf_2000)
24
25    WHERE 
26    {
27        SELECT  ?vestiging 
28                ?wooneenheid 
29                (SUM(?financialValue) AS ?sum_financialValue)
30        WHERE 
31        { 
32            ?wooneenheid a onz-org:WoonEenheid ;
33                onz-g:partOf ?locatie ;
34                onz-g:hasAttributedFinancialEntity ?financial_entity .
35            {
36            ?locatie 
37                a onz-org:Vestiging ;
38                onz-g:identifiedBy ?vest_nr.
39            ?vest_nr a onz-org:Vestigingsnummer ;
40                onz-g:hasDataValue ?vestiging .
41            } UNION 
42            {
43            #Includeer ook de organisatie als geheel en label deze als vestiging
44            ?locatie onz-org:vestigingVan ?organisatie_uri .
45            ?organisatie_uri 
46                a onz-g:Business ;
47                rdfs:label ?organisatie .
48            BIND(CONCAT('Totaal ',?organisatie) AS ?vestiging)
49            }
50
51            ?financial_entity a ?financial_entity_class; 
52                onz-g:hasQuality/onz-g:hasQualityValue/onz-g:hasDataValue ?financialValue .
53
54            FILTER(?financial_entity_class = onz-g:Rent || ?financial_entity_class = onz-fin:ServiceKostenBinnenHuurtoeslag)
55        } GROUP BY ?vestiging ?wooneenheid
56    } GROUP BY ?vestiging ?wooneenheid 
57} GROUP BY ?vestiging