1.5.1 Aantal wooneenheden onder en boven de sociale huurgrens

Concepten

• Bedrijf
• HuurBedrag
• Vestiging
• Vestigingsnummer
• Wooneenheid

Relaties

• deel van
• geïdentificeerd door
• heeft eigenschap of kenmerk
• heeft eigenschapswaarde
• heeftToegekendeFinanciëleEntiteit
• vestiging van

Eigenschappen

• heeft datawaarde

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Zorgkantoren Clientinformatie 1.5.1
2# Parameters: -
3# Ontologie: versie 2.2.0 of nieuwer
4
5PREFIX onz-org: <http://purl.org/ozo/onz-org#>
6PREFIX onz-g: <http://purl.org/ozo/onz-g#>
7PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
8PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
9PREFIX onz-fin: <http://purl.org/ozo/onz-fin#>
10
11
12SELECT  ?vestiging 
13		(COUNT(?wooneenheid) AS ?aantal_wooneenheden)
14        (SUM(?hoger_dan) AS ?boven_de_sociale_huurgrens)
15		(SUM(?lager_dan) AS ?onder_de_sociale_huurgrens)
16WHERE 
17{ 
18    SELECT  ?vestiging ?wooneenheid
19            (SUM(?sum_financialValue) AS ?totaal)
20            (IF(?totaal>"808.06"^^xsd:float,1, 0) AS ?hoger_dan)
21            (IF(?totaal<="808.06"^^xsd:float,1, 0) AS ?lager_dan)
22    WHERE 
23    {
24        SELECT  ?vestiging 
25                ?wooneenheid 
26                (SUM(?financialValue) AS ?sum_financialValue)
27        WHERE 
28        { 
29            ?wooneenheid a onz-org:WoonEenheid ;
30                onz-g:partOf ?locatie ;
31                onz-g:hasAttributedFinancialEntity ?financial_entity .
32            {
33            ?locatie 
34                a onz-org:Vestiging ;
35                onz-g:identifiedBy ?vest_nr.
36            ?vest_nr a onz-org:Vestigingsnummer ;
37                onz-g:hasDataValue ?vestiging .
38            } UNION 
39            {
40            #Includeer ook de organisatie als geheel en label deze als vestiging
41            ?locatie onz-org:vestigingVan ?organisatie_uri .
42            ?organisatie_uri 
43                a onz-g:Business ;
44                rdfs:label ?organisatie .
45            BIND(CONCAT('Totaal ',?organisatie) AS ?vestiging)
46            }
47
48            ?financial_entity a ?financial_entity_class; 
49                onz-g:hasQuality/onz-g:hasQualityValue/onz-g:hasDataValue ?financialValue .
50
51            FILTER(?financial_entity_class = onz-g:Rent || ?financial_entity_class = onz-fin:ServiceKostenBinnenHuurtoeslag)
52        } GROUP BY ?vestiging ?wooneenheid
53    } GROUP BY ?vestiging ?wooneenheid 
54} GROUP BY ?vestiging