99.2 In welke mate wordt rekening gehouden met mijn voedselvoorkeuren door deze vestiging?

Concepten

• Afspraak voedselvoorkeuren
• Verpleegproces
• Vestiging
• Vestigingsnummer

Relaties

• deel van
• gaat over
• gedefinieerd door
• geïdentificeerd door
• heeft deel
• heeft deelnemer
• heeft perdurantlocatie

Eigenschappen

• einddatum
• heeft datawaarde
• startdatum

Instanties

• VV Beschermd verblijf met intensieve palliatief-terminale zorg
• VV Beschermd wonen met intensieve dementiezorg
• VV Beschermd wonen met intensieve verzorging en verpleging
• VV Beschermd wonen met zeer intensieve zorg, vanwege specifieke aandoeningen, met de nadruk op begeleiding
• VV Beschermd wonen met zeer intensieve zorg, vanwege specifieke aandoeningen, met de nadruk op verzorging en verpleging
• VV Beschut wonen met intensieve begeleiding en uitgebreide verzorging
• VV Herstelgerichte behandeling met verpleging en verzorging

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Zorgkantoren clientinformatie 99.2
2# Parameters: -
3# Ontologie: versie 2.2.0 of nieuwer
4
5PREFIX onz-g: <http://purl.org/ozo/onz-g#>
6PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
7PREFIX onz-org: <http://purl.org/ozo/onz-org#>
8PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
9PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
10PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
11
12SELECT
13    ?vestiging
14    ?teller
15    ?noemer
16    ?indicator
17{
18    {
19        SELECT
20            ?vestiging
21            (SUM(?inclusie_teller) AS ?teller_temp)
22            (COUNT(?client) AS ?noemer_temp)
23            (ROUND(100 * SUM(?inclusie_teller) / COUNT(?client)) AS ?indicator_temp)
24        {
25            {
26                SELECT 
27                    ?client
28                    (MAX(?start_proces) AS ?start_laatste_proces) #zodat meest recente vestiging gevonden kan worden
29                    (MAX(?tlr) AS ?inclusie_teller) #MAX zodat een client maar 1x mee kan tellen
30                {
31                    BIND("2022-12-31"^^xsd:date AS ?peildatum)
32                    BIND(?peildatum - "P6M"^^xsd:duration + "P1D"^^xsd:duration AS ?start_periode)
33                    BIND(?peildatum AS ?eind_periode)
34
35                    VALUES ?zorgprofiel { onz-zorg:4VV onz-zorg:5VV onz-zorg:6VV onz-zorg:7VV onz-zorg:8VV onz-zorg:9BVV onz-zorg:10VV }
36                    
37                    #selecteer de zorgprocessen die voldoen aan de inclusiecriteria
38                    ?zorgproces
39                        a onz-zorg:NursingProcess ;
40                        onz-g:hasParticipant ?client ;
41                        onz-g:definedBy/onz-g:hasPart ?zorgprofiel ;
42                        onz-g:startDatum ?start_proces .
43                        OPTIONAL {?zorgproces onz-g:eindDatum ?eind_proces}
44                    FILTER (?start_proces <= ?eind_periode && (!BOUND(?eind_proces) || ?eind_proces >= ?start_periode))
45
46                    #selecteer eventuele beleidsafspraken rondom voedselvoorkeuren
47                    OPTIONAL {
48                        ?beleidsafspraak 
49                            a onz-zorg:AfspraakVoedselvoorkeuren ;
50                            onz-g:isAbout ?client ;
51                            onz-g:startDatum ?datum .
52                        FILTER (?datum >= ?start_periode && ?datum <= ?eind_periode)
53                    }
54                    BIND(IF(BOUND(?beleidsafspraak),1,0) AS ?tlr)
55                } 
56                GROUP BY ?client
57            }
58            #Vind de laatste vestiging binnen de verslagperiode en koppel deze aan de client
59            ?laatsteproces 
60                onz-g:hasParticipant ?client ;
61                onz-g:startDatum ?start_laatste_proces ;
62                onz-g:hasPerdurantLocation ?locatie .
63            ?locatie 
64                onz-g:partOf* ?vestiging_uri .
65            ?vestiging_uri 
66                a onz-org:Vestiging ;
67                onz-g:identifiedBy ?vest_nr .
68            ?vest_nr
69                a onz-org:Vestigingsnummer ;
70                onz-g:hasDataValue ?vestiging .
71        }
72        GROUP BY ?vestiging
73    }
74    #Corrigeer voor waarnemingen kleiner dan 10
75    #Houd rekening met een teller die mogelijk groter is dan de noemer
76    BIND (IF(?teller_temp < 10, "Waarneming kleiner dan 10", ?teller_temp) AS ?teller)
77    BIND (IF(?noemer_temp < 10, "Waarneming kleiner dan 10", ?noemer_temp) AS ?noemer)
78    BIND (IF(?teller_temp < 10, "Waarneming kleiner dan 10", ?indicator_temp) AS ?indicator)
79}
80