1.7 Aan hoeveel unieke cliënten is zorg verleend?

Concepten

• Mens
• ZorgEnVerpleegProces

Relaties

• heeft deelnemer

Eigenschappen

• einddatum
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: MEVA 1.7
2# Parameters: ?jaar
3# Ontologie: versie 3.0.0 of nieuwer
4
5PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
6PREFIX onz-org:  <http://purl.org/ozo/onz-org#>
7PREFIX onz-g:    <http://purl.org/ozo/onz-g#>
8PREFIX rdfs:     <http://www.w3.org/2000/01/rdf-schema#>
9PREFIX xsd:      <http://www.w3.org/2001/XMLSchema#>
10
11SELECT
12  ?Periode
13  (COUNT(DISTINCT ?client) AS ?Aantal_unieke_cliënten)
14WHERE {
15
16  {
17    #BIND(2024 AS ?jaar)
18    VALUES ?kw { 1 2 3 4 0 }
19
20    BIND( xsd:date(CONCAT(STR(?jaar), "-",
21           IF(?kw=1,"01-01", IF(?kw=2,"04-01", IF(?kw=3,"07-01", IF(?kw=4,"10-01", "01-01"))))
22         )) AS ?p_start )
23    BIND( xsd:date(CONCAT(STR(?jaar), "-",
24           IF(?kw=1,"03-31", IF(?kw=2,"06-30", IF(?kw=3,"09-30","12-31")))
25         )) AS ?p_eind )
26    BIND( IF(?kw = 0, "Totaal jaar", CONCAT("Q", STR(?kw))) AS ?Periode )
27  }
28
29  ?client a onz-g:Human .
30
31  ?zorgproces
32    a onz-g:CureAndCareProcess ;
33    onz-g:hasParticipant ?client ;
34    onz-g:startDatum ?start_zorgproces .
35
36  OPTIONAL { ?zorgproces onz-g:eindDatum ?eind_zorgproces }
37
38  FILTER (
39    ?start_zorgproces <= ?p_eind &&
40    (!BOUND(?eind_zorgproces) || ?eind_zorgproces >= ?p_start)
41  )
42}
43GROUP BY ?Periode
44ORDER BY ?Periode
45