2.8. Wat is het aantal leerlingen?

Concepten

• Arbeidsovereenkomst beroeps begeleidende leerweg
• Onverplaatsbaar artefact
• Vestiging
• Vestigingsnummer
• Werkovereenkomst afspraak
• Zorgkantoor regio

Relaties

• deel van
• gaat over
• geïdentificeerd door
• heeft deel
• heeft lokaliseerbaar gebied
• heeft opdrachtnemer
• opereert in regio
• vestiging van

Eigenschappen

• einddatum
• heeft datawaarde
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: MEVA 2.8
2# Parameters: ?jaar
3# Ontologie: versie 3.0 of nieuwer
4
5PREFIX onz-g: <http://purl.org/ozo/onz-g#>
6PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
7PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
8PREFIX onz-org: <http://purl.org/ozo/onz-org#>
9PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
10PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
11PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
12prefix time: <http://www.w3.org/2006/time#>
13
14SELECT ?Periode
15    (?vestiging AS ?Indeling)
16    (COUNT (DISTINCT ?persoon) AS ?Aantal_BBL_leerlingen)
17WHERE {
18      #BIND(2024 AS ?jaar)  
19      VALUES ?kw { 1 2 3 4 0 }
20
21      BIND( xsd:date(CONCAT(STR(?jaar), "-",
22                        IF(?kw=1,"01-01", IF(?kw=2,"04-01", IF(?kw=3,"07-01", IF(?kw=4,"10-01", "01-01"))))
23           )) AS ?p_start )
24      BIND( xsd:date(CONCAT(STR(?jaar), "-",
25               IF(?kw=1,"03-31", IF(?kw=2,"06-30", IF(?kw=3,"09-30","12-31")))
26           )) AS ?p_eind )
27      BIND( IF(?kw = 0, "Totaal jaar", CONCAT("Q", STR(?kw))) AS ?Periode )
28
29    
30    VALUES ?personeels_overeenkomst { 
31        onz-pers:ArbeidsOvereenkomstBBL }
32
33    #Selecteer alle personeelsleden met een BBL overeenkomst binnen de meetperiode
34    ?overeenkomst 
35        a ?personeels_overeenkomst ;
36        onz-pers:heeftOpdrachtnemer ?persoon ;
37        onz-g:hasPart ?overeenkomst_afspraak .
38    ?overeenkomst_afspraak
39        a onz-pers:WerkOvereenkomstAfspraak ;
40        onz-g:isAbout ?locatie ;
41        onz-g:startDatum ?start_afspraak .
42    OPTIONAL { ?overeenkomst_afspraak onz-g:eindDatum ?eind_afspraak . }
43
44    FILTER (?start_afspraak <= ?p_eind && (?eind_afspraak >= ?p_start || !BOUND(?eind_afspraak)))
45  
46        ?locatie 
47            a onz-g:StationaryArtifact ;
48        	onz-g:partOf* ?vestiging_uri .
49        ?vestiging_uri a onz-org:Vestiging ;
50            onz-g:hasLocalizableArea/onz-g:identifiedBy/onz-g:hasPart/onz-g:hasPart ?postcode_6 .
51        BIND(IRI(SUBSTR(STR(?postcode_6), 1, STRLEN(STR(?postcode_6)) - 2)) AS ?postcode)
52        ?pc_gebied 
53            onz-g:identifiedBy ?postcode ;
54            onz-g:partOf+ ?zk_regio .
55        ?zk_regio a onz-org:ZorgkantoorRegio .
56        ?zorgkantoor onz-g:hasOperatingRange ?zk_regio .
57
58        {     
59            ?vestiging_uri onz-g:identifiedBy ?vest_nr .    	
60            ?vest_nr a onz-org:Vestigingsnummer ;
61            	onz-g:hasDataValue ?vestiging .
62        } UNION {
63            # Includeer ook de organisatie als geheel en label deze als vestiging
64            ?vestiging_uri onz-org:vestigingVan ?organisatie_uri .
65            BIND("Totaal organisatie" AS ?vestiging)
66            BIND("n.v.t." AS ?zk_vestiging)
67        }
68        BIND(IF(!BOUND(?zk_vestiging), ?zorgkantoor, ?zk_vestiging) AS ?zorgkantoor_vestiging)
69    }
70GROUP BY ?Periode ?vestiging ?zorgkantoor_vestiging
71ORDER BY ?Periode ?vestiging