2.17. Wat is het gemiddeld aantal ingezette FTE personeel in loondienst (PIL) met een zorgfunctie per kwartaal?

Concepten

• Arbeidsovereenkomst
• Gewerkte periode
• Werkovereenkomst afspraak
• Zorgverlener (functie)

Relaties

• gaat over
• gedefinieerd door
• heeft deel
• heeft eigenschap of kenmerk
• heeft eigenschapswaarde
• heeft opdrachtnemer

Eigenschappen

• einddatum
• heeft datawaarde
• heeftBeginTijd
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: MEVA 2.17
2# Parameters: ?jaar
3# Ontologie: versie 3.0
4
5PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
6PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
7PREFIX onz-g: <http://purl.org/ozo/onz-g#>
8PREFIX onz-org: <http://purl.org/ozo/onz-org#>
9PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
10
11SELECT ?Periode ?Aantal_FTE
12WHERE {
13  {
14    SELECT ?Periode
15           (FLOOR(SUM(?inzet_uren) / 141 / IF(?Periode = "Totaal jaar", 12, 3)) AS ?Aantal_FTE)
16    WHERE {
17      #BIND(2024 AS ?jaar)            
18      VALUES ?kw { 1 2 3 4 0 }
19
20      BIND( xsd:date(CONCAT(STR(?jaar), "-",
21                        IF(?kw=1,"01-01", IF(?kw=2,"04-01", IF(?kw=3,"07-01", IF(?kw=4,"10-01", "01-01"))))
22           )) AS ?p_start )
23      BIND( xsd:date(CONCAT(STR(?jaar), "-",
24               IF(?kw=1,"03-31", IF(?kw=2,"06-30", IF(?kw=3,"09-30","12-31")))
25           )) AS ?p_eind )
26      BIND( IF(?kw = 0, "Totaal jaar", CONCAT("Q", STR(?kw))) AS ?Periode )
27		
28      ?overeenkomst
29          a onz-pers:ArbeidsOvereenkomst ;
30          onz-pers:heeftOpdrachtnemer ?persoon ;
31          onz-g:startDatum ?start_overeenkomst ;
32          onz-g:hasPart ?overeenkomst_afspraak .
33      OPTIONAL { ?overeenkomst onz-g:eindDatum ?eind_overeenkomst }
34      FILTER (?start_overeenkomst  <= ?p_eind && (?eind_overeenkomst >= ?p_start || !BOUND(?eind_overeenkomst)))
35
36      ?overeenkomst_afspraak
37          a onz-pers:WerkOvereenkomstAfspraak ;
38          onz-g:isAbout ?functie ;
39          onz-g:startDatum ?start_afspraak .
40      OPTIONAL { ?overeenkomst_afspraak onz-g:eindDatum ?eind_afspraak }
41      FILTER (?start_afspraak <= ?p_eind && (?eind_afspraak >= ?p_start || !BOUND(?eind_afspraak)))
42
43      ?functie a onz-pers:ZorgverlenerFunctie .
44
45      ?inzet
46          a onz-pers:GewerktePeriode ;
47          onz-g:definedBy ?overeenkomst ;
48          onz-g:hasBeginTimeStamp ?start_inzet_datetime ;
49          onz-g:hasQuality/onz-g:hasQualityValue/onz-g:hasDataValue ?inzet_uren .
50      BIND(STRDT(SUBSTR(STR(?start_inzet_datetime), 1, 10), xsd:date) AS ?start_inzet)
51      FILTER(?start_inzet >= ?p_start && ?start_inzet <= ?p_eind)
52      FILTER(?start_inzet >= ?start_afspraak && (?start_inzet <= ?eind_afspraak || !BOUND(?eind_afspraak)))
53
54    }
55    GROUP BY ?Periode
56  }
57}
58ORDER BY ?Periode
59