2.6. Welk deel van de arbeidsovereenkomsten is voor bepaalde tijd?

Concepten

• Arbeidsovereenkomst bepaalde tijd
• Arbeidsovereenkomst onbepaalde tijd
• Onverplaatsbaar artefact
• Vestiging
• Vestigingsnummer
• Werkovereenkomst afspraak
• Zorgkantoor regio

Relaties

• deel van
• gaat over
• geïdentificeerd door
• heeft deel
• heeft lokaliseerbaar gebied
• opereert in regio
• vestiging van

Eigenschappen

• einddatum
• heeft datawaarde
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: MEVA 2.6
2# Parameters: ?jaar
3# Ontologie: versie 3.0 of nieuwer
4
5PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
6PREFIX onz-g:    <http://purl.org/ozo/onz-g#>
7PREFIX onz-org:  <http://purl.org/ozo/onz-org#>
8PREFIX rdfs:     <http://www.w3.org/2000/01/rdf-schema#>
9PREFIX xsd:      <http://www.w3.org/2001/XMLSchema#>
10
11SELECT
12    ?Periode
13    (?vestiging AS ?Indeling)
14    (SUM(?bepaald_flag) AS ?Aantal_arbeidsovereenkomsten_bepaalde_tijd)
15    ((SUM(?bepaald_flag) + SUM(?onbepaald_flag)) AS ?Aantal_arbeidsovereenkomsten_voor_bepaalde_en_onbepaalde_tijd)
16    (IF( (SUM(?bepaald_flag) + SUM(?onbepaald_flag)) > 0,
17        ROUND(10000 * SUM(?bepaald_flag) / (SUM(?bepaald_flag) + SUM(?onbepaald_flag))) / 100 ,
18        0
19    ) AS ?Percentage_bepaalde_tijd)
20WHERE {
21    {
22    SELECT
23        ?Periode
24        ?vestiging
25        ?overeenkomst
26        (MAX(?is_bepaald)   AS ?bepaald_flag)
27        (MAX(?is_onbepaald) AS ?onbepaald_flag)
28    WHERE {
29        # BIND(2023 AS ?jaar)
30
31        VALUES ?kw { 1 2 3 4 0 }  # 0 = Totaal jaar
32        BIND(xsd:integer(?jaar) AS ?_jaar)
33
34        BIND( IF(?kw=0,
35                xsd:date(CONCAT(STR(?_jaar), "-01-01")),
36                xsd:date(CONCAT(STR(?_jaar), "-",
37                                IF(?kw=1,"01-01",
38                                    IF(?kw=2,"04-01",
39                                    IF(?kw=3,"07-01","10-01")))))
40                ) AS ?p_start )
41
42        BIND( IF(?kw=0,
43                xsd:date(CONCAT(STR(?_jaar), "-12-31")),
44                xsd:date(CONCAT(STR(?_jaar), "-",
45                                IF(?kw=1,"03-31",
46                                    IF(?kw=2,"06-30",
47                                    IF(?kw=3,"09-30","12-31")))))
48                ) AS ?p_eind )
49
50        BIND( IF(?kw=0, "Totaal jaar", CONCAT("Q", STR(?kw))) AS ?Periode )
51
52        VALUES ?type_overeenkomst {
53        onz-pers:ArbeidsOvereenkomstBepaaldeTijd
54        onz-pers:ArbeidsOvereenkomstOnbepaaldeTijd
55        }
56
57        ?overeenkomst a ?type_overeenkomst ;
58                    onz-g:hasPart ?overeenkomst_afspraak .
59
60        ?overeenkomst_afspraak
61            a onz-pers:WerkOvereenkomstAfspraak ;
62            onz-g:isAbout ?locatie ;
63            onz-g:startDatum ?start_afspraak .
64        OPTIONAL { ?overeenkomst_afspraak onz-g:eindDatum ?eind_afspraak }
65
66        FILTER( ?start_afspraak <= ?p_eind &&
67                ( !BOUND(?eind_afspraak) || ?eind_afspraak >= ?p_start ) )
68
69        ?locatie a onz-g:StationaryArtifact ;
70                onz-g:partOf* ?vestiging_uri .
71        ?vestiging_uri a onz-org:Vestiging ;
72        onz-g:hasLocalizableArea/onz-g:identifiedBy/onz-g:hasPart/onz-g:hasPart ?postcode_6 .
73
74        BIND( IRI(SUBSTR(STR(?postcode_6), 1, STRLEN(STR(?postcode_6)) - 2)) AS ?postcode )
75        ?pc_gebied onz-g:identifiedBy ?postcode ;
76                    onz-g:partOf+ ?zk_regio .
77        ?zk_regio a onz-org:ZorgkantoorRegio .
78        ?zorgkantoor onz-g:hasOperatingRange ?zk_regio .
79
80        {
81        ?vestiging_uri onz-g:identifiedBy ?vest_nr .
82        ?vest_nr a onz-org:Vestigingsnummer ;
83                    onz-g:hasDataValue ?vestiging .
84        }
85        UNION
86        {
87        ?vestiging_uri onz-org:vestigingVan ?organisatie_uri .
88        BIND("Totaal organisatie" AS ?vestiging)
89        BIND("n.v.t." AS ?zk_vestiging)
90        }
91
92        BIND(IF(!BOUND(?zk_vestiging), ?zorgkantoor, ?zk_vestiging) AS ?zorgkantoor_vestiging)
93
94        BIND( IF(?type_overeenkomst = onz-pers:ArbeidsOvereenkomstBepaaldeTijd,   1, 0) AS ?is_bepaald )
95        BIND( IF(?type_overeenkomst = onz-pers:ArbeidsOvereenkomstOnbepaaldeTijd, 1, 0) AS ?is_onbepaald )
96    }
97    GROUP BY ?Periode ?vestiging ?overeenkomst
98    }
99}
100GROUP BY ?Periode ?vestiging
101
102ORDER BY
103    (IF(?Periode = "Totaal jaar", 0, xsd:integer(SUBSTR(?Periode, 2))))
104    (IF(?Indeling = "Totaal organisatie", 0, 1))
105    ?Indeling
106