2.11. Wat is het aantal personeelsleden?

Concepten

• Arbeidsovereenkomst
• Functie in organisatie-rol
• Inhuurovereenkomst
• Onverplaatsbaar artefact
• Uitzendovereenkomst
• Vestiging
• Vestigingsnummer
• Werkovereenkomst afspraak
• Zorgkantoor regio
• Zorgverlener (functie)

Relaties

• deel van
• gaat over
• geïdentificeerd door
• heeft deel
• heeft lokaliseerbaar gebied
• heeft opdrachtnemer
• opereert in regio
• vestiging van

Eigenschappen

• einddatum
• heeft datawaarde
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: MEVA 2.11
2# Parameters: ?jaar
3# Ontologie: versie 3.0.0 of nieuwer
4
5PREFIX onz-org: <http://purl.org/ozo/onz-org#>
6PREFIX onz-g:   <http://purl.org/ozo/onz-g#>
7PREFIX onz-pers:<http://purl.org/ozo/onz-pers#>
8PREFIX xsd:     <http://www.w3.org/2001/XMLSchema#>
9
10SELECT ?Periode
11       (?vestiging AS ?Indeling)
12       (SUM(?zorg_functie) AS ?Zorg)
13       (SUM(?niet_zorg_functie) AS ?Niet_zorg)
14       (COUNT(DISTINCT ?persoon) AS ?Totaal)
15WHERE {
16  {
17    SELECT
18      ?Periode
19      ?vestiging
20      ?persoon
21      (MAX(?zorg) AS ?zorg_functie)
22      (MAX(?niet_zorg) AS ?niet_zorg_functie)
23    WHERE {
24      #BIND(2023 AS ?jaar)            
25      VALUES ?kw { 1 2 3 4 0 }
26
27      BIND( xsd:date(CONCAT(STR(?jaar), "-",
28                        IF(?kw=1,"01-01", IF(?kw=2,"04-01", IF(?kw=3,"07-01", IF(?kw=4,"10-01", "01-01"))))
29           )) AS ?p_start )
30      BIND( xsd:date(CONCAT(STR(?jaar), "-",
31               IF(?kw=1,"03-31", IF(?kw=2,"06-30", IF(?kw=3,"09-30","12-31")))
32           )) AS ?p_eind )
33	 BIND( IF(?kw = 0, "Totaal jaar", CONCAT("Q", STR(?kw))) AS ?Periode )
34
35      VALUES ?personeels_overeenkomst {
36        onz-pers:ArbeidsOvereenkomst
37        onz-pers:UitzendOvereenkomst
38        onz-pers:InhuurOvereenkomst
39      }
40      ?overeenkomst a ?personeels_overeenkomst ;
41                    onz-pers:heeftOpdrachtnemer ?persoon ;
42                    onz-g:hasPart ?overeenkomst_afspraak .
43      ?overeenkomst_afspraak
44           a onz-pers:WerkOvereenkomstAfspraak ;
45           onz-g:isAbout ?functie ;
46           onz-g:isAbout ?locatie ;
47           onz-g:startDatum ?start_afspraak .
48      OPTIONAL { ?overeenkomst_afspraak onz-g:eindDatum ?eind_afspraak }
49
50      FILTER( ?start_afspraak <= ?p_eind &&
51              ( !BOUND(?eind_afspraak) || ?eind_afspraak >= ?p_start ) )
52
53      ?functie a onz-g:OccupationalPositionRole .
54      BIND( IF(EXISTS { ?functie a onz-pers:ZorgverlenerFunctie }, 1, 0) AS ?zorg )
55      BIND( IF(?zorg = 0, 1, 0) AS ?niet_zorg )
56
57      # Locatie -> Vestiging (incl. 'Totaal organisatie')
58      ?locatie a onz-g:StationaryArtifact .
59      ?locatie onz-g:partOf* ?vestiging_uri .
60      ?vestiging_uri a onz-org:Vestiging ;
61        onz-g:hasLocalizableArea/onz-g:identifiedBy/onz-g:hasPart/onz-g:hasPart ?postcode_6 .
62      BIND( IRI(SUBSTR(STR(?postcode_6), 1, STRLEN(STR(?postcode_6)) - 2)) AS ?postcode )
63      ?pc_gebied onz-g:identifiedBy ?postcode ;
64                 onz-g:partOf+ ?zk_regio .
65      ?zk_regio a onz-org:ZorgkantoorRegio .
66      ?zorgkantoor onz-g:hasOperatingRange ?zk_regio .
67
68      { ?vestiging_uri onz-g:identifiedBy ?vest_nr .
69        ?vest_nr a onz-org:Vestigingsnummer ;
70                 onz-g:hasDataValue ?vestiging .
71      }
72      UNION
73      { ?vestiging_uri onz-org:vestigingVan ?organisatie_uri .
74        BIND("Totaal organisatie" AS ?vestiging)
75      }
76    }
77    GROUP BY ?Periode ?vestiging ?persoon
78  }
79  
80}
81GROUP BY ?Periode ?vestiging
82ORDER BY ?Periode ?vestiging
83