2.14. Welk deel van de ingezette uren personeel is door PNIL?

Concepten

• Arbeidsovereenkomst
• Gewerkte periode
• Inhuurovereenkomst
• Onverplaatsbaar artefact
• Uitzendovereenkomst
• Vestiging
• Vestigingsnummer
• Werkovereenkomst afspraak

Relaties

• deel van
• gaat over
• gedefinieerd door
• geïdentificeerd door
• heeft deel
• heeft eigenschap of kenmerk
• heeft eigenschapswaarde
• heeft opdrachtnemer
• heeft perdurantlocatie
• vestiging van

Eigenschappen

• einddatum
• heeft datawaarde
• heeftBeginTijd
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: MEVA 2.14
2# Parameters: ?jaar
3# Ontologie: versie 3.0 of nieuwer
4
5PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
6PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
7PREFIX onz-g: <http://purl.org/ozo/onz-g#>
8PREFIX onz-org: <http://purl.org/ozo/onz-org#>
9PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
10
11SELECT ?Periode
12    (?vestiging AS ?Indeling)
13    (SUM(?uren * ?pnil) AS ?Ingezette_uren_PNIL)
14    (SUM(?uren * ?pil) AS ?Ingezette_uren_PIL)
15    (IF(SUM(?uren)=0, "Ongedefinieerd",
16      ROUND( (100.0 * SUM(?uren * ?pnil) / SUM(?uren)) * 100 ) / 100.0)
17      AS ?Percentage_ingezette_uren_PNIL)
18{
19	  #BIND(2024 AS ?jaar)  
20      VALUES ?kw { 1 2 3 4 0 }
21
22      BIND( xsd:date(CONCAT(STR(?jaar), "-",
23                        IF(?kw=1,"01-01", IF(?kw=2,"04-01", IF(?kw=3,"07-01", IF(?kw=4,"10-01", "01-01"))))
24           )) AS ?p_start )
25      BIND( xsd:date(CONCAT(STR(?jaar), "-",
26               IF(?kw=1,"03-31", IF(?kw=2,"06-30", IF(?kw=3,"09-30","12-31")))
27           )) AS ?p_eind )
28      BIND( IF(?kw = 0, "Totaal jaar", CONCAT("Q", STR(?kw))) AS ?Periode )
29
30    VALUES ?type_overeenkomst {onz-pers:ArbeidsOvereenkomst onz-pers:InhuurOvereenkomst onz-pers:UitzendOvereenkomst}
31    
32    ?overeenkomst 
33        a ?type_overeenkomst ; # personeel in loondienst (arbeidsovereenkomst) en personeel niet in loondienst (inhuur- en uitzendovereenkomst)
34        onz-pers:heeftOpdrachtnemer ?persoon ;
35        onz-g:hasPart ?overeenkomst_afspraak .
36    ?overeenkomst_afspraak
37        a onz-pers:WerkOvereenkomstAfspraak ;
38        onz-g:startDatum ?start_afspraak ;
39    	onz-g:isAbout ?locatie_afspraak .  
40    OPTIONAL { ?overeenkomst_afspraak onz-g:eindDatum ?eind_afspraak }
41    FILTER(?start_afspraak <= ?p_eind && ((?eind_afspraak >= ?p_start) || (!BOUND(?eind_afspraak))))
42
43    ?locatie_afspraak a onz-g:StationaryArtifact .
44
45    ?inzet
46        a onz-pers:GewerktePeriode ;
47        onz-g:definedBy ?overeenkomst ;
48        onz-g:hasBeginTimeStamp ?start_inzet_datetime ;
49        onz-g:hasQuality/onz-g:hasQualityValue/onz-g:hasDataValue ?uren .
50    OPTIONAL{ ?inzet onz-g:hasPerdurantLocation ?locatie_werk }
51    BIND(STRDT(SUBSTR(STR(?start_inzet_datetime), 1, 10), xsd:date) AS ?start_inzet)
52    FILTER(?start_inzet >= ?p_start && ?start_inzet <= ?p_eind)
53    FILTER(?start_inzet >= ?start_afspraak && (?start_inzet <= ?eind_afspraak || !BOUND(?eind_afspraak)))
54
55    # Bepaal de locatie voor uren. Gebruik urenregistratie. Als die geen locatie bevat, gebruik locatie van contract
56    BIND(IF(!BOUND(?locatie_werk), ?locatie_afspraak, ?locatie_werk) AS ?locatie)
57    ?locatie onz-g:partOf* ?vestiging_uri .
58    ?vestiging_uri a onz-org:Vestiging .
59    {     
60        ?vestiging_uri onz-g:identifiedBy ?vest_nr .    	
61        ?vest_nr a onz-org:Vestigingsnummer ;
62            onz-g:hasDataValue ?vestiging .
63    } UNION {
64        # Includeer ook de organisatie als geheel en label deze als vestiging
65        ?vestiging_uri onz-org:vestigingVan ?organisatie_uri .
66        BIND("Totaal organisatie" AS ?vestiging)
67    }
68	BIND(IF (?type_overeenkomst = onz-pers:ArbeidsOvereenkomst, 1, 0) AS ?pil)
69    BIND(IF (?pil = 0, 1, 0) AS ?pnil)
70
71}
72GROUP BY ?Periode ?vestiging ?zorgkantoor_vestiging
73ORDER BY ?Periode ?vestiging ?zorgkantoor_vestiging
74