Uitwisselprofiel Ministerie van VWS Beleidsontwikkeling over Macro Economische Vraagstukken en Arbeidsmarkt

Over Uitwisselprofiel Ministerie van VWS Beleidsontwikkeling over Macro Economische Vraagstukken en Arbeidsmarkt

Publicatiedatum:
19-11-2025
Inwerkingtreding:
19-11-2025
Bekijk bron...

2.19. Wat is de verhouding tussen het aantal personeelsleden met een zorgverlenersfunctie en het aantal cliënten?

Concepten

Relaties

Eigenschappen

Instanties

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: MEVA 2.19
2# Parameters: ?jaar
3# Ontologie: versie 3.0.0 of nieuwer
4
5PREFIX onz-g: <http://purl.org/ozo/onz-g#>
6PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
7PREFIX onz-org: <http://purl.org/ozo/onz-org#>
8PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
9PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
10PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
11PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
12PREFIX time: <http://www.w3.org/2006/time#>
13
14SELECT 
15    ?Periode
16    (?vestiging AS ?Indeling)
17    (?zk_regio_code AS ?Zorgkantoorregiocode)
18    ?Aantal_ingezette_uren
19    ?Aantal_ligdagen
20	(IF(?Aantal_ingezette_uren != 0, ROUND( (?Aantal_ligdagen / (?Aantal_ingezette_uren / 24)) * 100 ) / 100,"Ongedefinieerd")  AS ?Aantal_cliënten_tov_1_medewerker)
21WHERE {
22  {
23    SELECT
24      ?Periode
25      ?vestiging
26      ?zorgkantoor_vestiging
27      ?zk_regio_code
28      (SUM(?gewerkte_uren) AS ?Aantal_ingezette_uren)
29    WHERE {
30      #BIND(2024 AS ?jaar)
31      VALUES ?kw { 1 2 3 4 0 }
32
33      BIND( xsd:date(CONCAT(STR(?jaar), "-",
34            IF(?kw=1,"01-01", IF(?kw=2,"04-01", IF(?kw=3,"07-01", IF(?kw=4,"10-01","01-01"))))
35          )) AS ?p_start )
36      BIND( xsd:date(CONCAT(STR(?jaar), "-",
37            IF(?kw=1,"03-31", IF(?kw=2,"06-30", IF(?kw=3,"09-30","12-31")))
38          )) AS ?p_eind )
39      BIND( IF(?kw = 0, "Totaal jaar", CONCAT("Q", STR(?kw))) AS ?Periode )
40
41      ?overeenkomst 
42        a onz-pers:WerkOvereenkomst ;
43        onz-g:hasPart ?overeenkomst_afspraak .
44      ?overeenkomst_afspraak
45        a onz-pers:WerkOvereenkomstAfspraak ;
46        onz-g:isAbout / a onz-pers:ZorgverlenerFunctie ;
47        onz-g:isAbout ?locatie_afspraak ;
48        onz-g:startDatum ?start_afspraak .
49      OPTIONAL { ?overeenkomst_afspraak onz-g:eindDatum ?eind_afspraak . }
50      ?locatie_afspraak a onz-g:StationaryArtifact .
51
52      FILTER(?start_afspraak <= ?p_eind && ((?eind_afspraak >= ?p_start) || (!BOUND(?eind_afspraak))))
53      BIND(IF(?start_afspraak < ?p_start, ?p_start, ?start_afspraak) AS ?start_afspraak_corr)
54      BIND(IF(?eind_afspraak > ?p_eind || !BOUND(?eind_afspraak), ?p_eind, ?eind_afspraak) AS ?eind_afspraak_corr)
55
56      ?inzet
57        a onz-pers:GewerktePeriode ;
58        onz-g:definedBy ?overeenkomst ;
59        onz-g:hasBeginTimeStamp ?start_inzet_datetime ;
60        onz-g:hasQuality/onz-g:hasQualityValue/onz-g:hasDataValue ?gewerkte_uren .
61      OPTIONAL { ?inzet onz-g:hasPerdurantLocation ?locatie_inzet . }
62      BIND(STRDT(SUBSTR(STR(?start_inzet_datetime), 1, 10), xsd:date) AS ?start_inzet)
63
64      FILTER(?start_inzet >= ?start_afspraak_corr && (?start_inzet <= ?eind_afspraak_corr || !BOUND(?eind_afspraak_corr)))
65      BIND(IF(BOUND(?locatie_inzet), ?locatie_inzet, ?locatie_afspraak) AS ?locatie)
66
67      ?locatie a onz-g:StationaryArtifact .
68      ?locatie onz-g:partOf* ?vestiging_uri .
69      ?vestiging_uri a onz-org:Vestiging ;
70        onz-g:hasLocalizableArea/onz-g:identifiedBy/onz-g:hasPart/onz-g:hasPart ?postcode_6 .
71      BIND(IRI(SUBSTR(STR(?postcode_6), 1, STRLEN(STR(?postcode_6)) - 2)) AS ?postcode)
72      ?pc_gebied onz-g:identifiedBy ?postcode ;
73                 onz-g:partOf+ ?zk_regio .
74      ?zk_regio a onz-org:ZorgkantoorRegio .
75      ?zorgkantoor onz-g:hasOperatingRange ?zk_regio .
76      {
77        ?vestiging_uri onz-g:identifiedBy ?vest_nr .
78        ?vest_nr a onz-org:Vestigingsnummer ;
79                 onz-g:hasDataValue ?vestiging .
80        BIND(STRAFTER(STR(?zk_regio), "onz-org/") AS ?zk_regio_code)
81      } UNION {
82        ?vestiging_uri onz-org:vestigingVan ?organisatie_uri .
83        BIND("Totaal organisatie" AS ?vestiging)
84        BIND("n.v.t." AS ?zk_vestiging)
85        BIND("n.v.t." AS ?zk_regio_code)
86      }
87      BIND(IF(!BOUND(?zk_vestiging), ?zorgkantoor, ?zk_vestiging) AS ?zorgkantoor_vestiging)
88    }
89    GROUP BY ?Periode ?vestiging ?zorgkantoor_vestiging ?zk_regio_code
90  }
91
92  {
93    SELECT
94      ?Periode
95      ?vestiging
96      ?zorgkantoor_vestiging
97      ?zk_regio_code
98      (SUM(?ligdagen) AS ?Aantal_ligdagen)
99    WHERE {
100      #BIND(2024 AS ?jaar)
101      VALUES ?kw { 1 2 3 4 0 }
102
103      # Periode-bepaling (zelfde patroon)
104      BIND( xsd:date(CONCAT(STR(?jaar), "-",
105            IF(?kw=1,"01-01", IF(?kw=2,"04-01", IF(?kw=3,"07-01", IF(?kw=4,"10-01","01-01"))))
106          )) AS ?start_periode )
107      BIND( xsd:date(CONCAT(STR(?jaar), "-",
108            IF(?kw=1,"03-31", IF(?kw=2,"06-30", IF(?kw=3,"09-30","12-31")))
109          )) AS ?eind_periode )
110      BIND( IF(?kw = 0, "Totaal jaar", CONCAT("Q", STR(?kw))) AS ?Periode )
111
112      VALUES ?zorgprofiel { onz-zorg:4VV onz-zorg:5VV onz-zorg:6VV onz-zorg:7VV onz-zorg:8VV onz-zorg:9BVV onz-zorg:10VV }
113
114      ?indicatie 
115        a onz-zorg:WlzIndicatie ;
116        onz-g:startDatum ?start_indicatie ;
117        onz-g:hasPart ?zorgprofiel ;
118        onz-g:hasPart onz-zorg:instelling ;
119        onz-g:isAbout ?client .
120      OPTIONAL { ?indicatie onz-g:eindDatum ?eind_indicatie . }
121      ?client a onz-g:Human .
122
123      FILTER(?start_indicatie <= ?eind_periode && ((?eind_indicatie >= ?start_periode) || (!BOUND(?eind_indicatie))))
124      BIND(IF(?start_indicatie < ?start_periode, ?start_periode, ?start_indicatie) AS ?start_indicatie_corr)
125      BIND(IF(?eind_indicatie > ?eind_periode || !BOUND(?eind_indicatie), ?eind_periode, ?eind_indicatie) AS ?eind_indicatie_corr)
126
127      ?zorgproces
128        a onz-zorg:NursingProcess ;
129        onz-g:definedBy ?indicatie ;
130        onz-g:hasPerdurantLocation ?locatie ;
131        onz-g:startDatum ?start_zorgproces .
132      OPTIONAL { ?zorgproces onz-g:eindDatum ?eind_zorgproces . }
133      FILTER(?start_zorgproces <= ?eind_periode && ((?eind_zorgproces >= ?start_periode) || (!BOUND(?eind_zorgproces))))
134      BIND(IF(?start_zorgproces < ?start_indicatie_corr, ?start_indicatie_corr, ?start_zorgproces) AS ?start_zorgproces_corr)
135      BIND(IF(?eind_zorgproces > ?eind_indicatie_corr || !BOUND(?eind_indicatie), ?eind_indicatie_corr, ?eind_indicatie) AS ?eind_zorgproces_corr)
136
137      ?start_zorgproces_corr ^time:inXSDDate/time:inTemporalPosition/time:numericPosition ?start_dag_reken .
138      ?eind_zorgproces_corr ^time:inXSDDate/time:inTemporalPosition/time:numericPosition ?eind_dag_reken .
139      BIND(?eind_dag_reken - ?start_dag_reken + 1 AS ?ligdagen)
140
141      ?locatie onz-g:partOf* ?vestiging_uri .
142      ?vestiging_uri a onz-org:Vestiging ;
143        onz-g:hasLocalizableArea/onz-g:identifiedBy/onz-g:hasPart/onz-g:hasPart ?postcode_6 .
144      BIND(IRI(SUBSTR(STR(?postcode_6), 1, STRLEN(STR(?postcode_6)) - 2)) AS ?postcode)
145      ?pc_gebied onz-g:identifiedBy ?postcode ;
146                 onz-g:partOf+ ?zk_regio .
147      ?zk_regio a onz-org:ZorgkantoorRegio .
148      ?zorgkantoor onz-g:hasOperatingRange ?zk_regio .
149      {
150        ?vestiging_uri onz-g:identifiedBy ?vest_nr .
151        ?vest_nr a onz-org:Vestigingsnummer ;
152                 onz-g:hasDataValue ?vestiging .
153        BIND(STRAFTER(STR(?zk_regio), "onz-org/") AS ?zk_regio_code)
154      } UNION {
155        ?vestiging_uri onz-org:vestigingVan ?organisatie_uri .
156        BIND("Totaal organisatie" AS ?vestiging)
157        BIND("n.v.t." AS ?zk_vestiging)
158        BIND("n.v.t." AS ?zk_regio_code)
159      }
160      BIND(IF(!BOUND(?zk_vestiging), ?zorgkantoor, ?zk_vestiging) AS ?zorgkantoor_vestiging)
161    }
162    GROUP BY ?Periode ?vestiging ?zorgkantoor_vestiging ?zk_regio_code
163  }
164}
165ORDER BY ?Periode ?Indeling
166
Terug naar: 2.17. Wat is het gemiddeld aantal ingezette FTE personeel in loondienst (PIL) met een zorgfunctie per kwartaal?