5.1. Wat is het aantal cliënten per leveringsvorm VPT, MPT, DTV en PGB?

Concepten

• Leveringsvorm
• Mens
• Wlz-indicatie
• ZorgEnVerpleegProces

Relaties

• gaat over
• gedefinieerd door
• heeft deel

Eigenschappen

• einddatum
• startdatum

Instanties

• Modulair pakket thuis
• Persoonsgebonden budget
• Verblijf in een instelling
• Volledig pakket thuis

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: MECA 5.1
2# Parameters: ?jaar
3# Ontologie: versie 3.0 of nieuwer
4
5PREFIX onz-g:   <http://purl.org/ozo/onz-g#>
6PREFIX onz-zorg:<http://purl.org/ozo/onz-zorg#>
7PREFIX rdfs:    <http://www.w3.org/2000/01/rdf-schema#>
8PREFIX xsd:     <http://www.w3.org/2001/XMLSchema#>
9
10SELECT
11  ?Periode
12  ("Totaal organisatie" AS ?Indeling)
13  (SUM(?hasVPT) AS ?Aantal_VPT)
14  (SUM(?hasMPT) AS ?Aantal_MPT)
15  (SUM(?hasDTV) AS ?Aantal_DTV)
16  (SUM(?hasPGB) AS ?Aantal_PGB)
17WHERE {
18  {
19    SELECT
20      ?Periode
21      ?client
22      (MAX(?vpt) AS ?hasVPT)
23      (MAX(?mpt) AS ?hasMPT)
24      (MAX(?pgb) AS ?hasPGB)
25      (MAX(?verblijf) AS ?hasVerblijf)
26    WHERE {
27            
28      #BIND(2024 AS ?jaar)  
29      VALUES ?kw { 1 2 3 4 0 }
30
31      BIND( xsd:date(CONCAT(STR(?jaar), "-",
32                        IF(?kw=1,"01-01", IF(?kw=2,"04-01", IF(?kw=3,"07-01", IF(?kw=4,"10-01", "01-01"))))
33           )) AS ?p_start )
34      BIND( xsd:date(CONCAT(STR(?jaar), "-",
35               IF(?kw=1,"03-31", IF(?kw=2,"06-30", IF(?kw=3,"09-30","12-31")))
36           )) AS ?p_eind )
37      BIND( IF(?kw = 0, "Totaal jaar", CONCAT("Q", STR(?kw))) AS ?Periode )
38
39      ?zorgproces a onz-g:CureAndCareProcess ;
40                  onz-g:definedBy ?indicatie ;
41                  onz-g:startDatum ?start_zorgproces .
42      OPTIONAL { ?zorgproces onz-g:eindDatum ?eind_zorgproces }
43      FILTER(?start_zorgproces <= ?p_eind && ( !BOUND(?eind_zorgproces) || ?eind_zorgproces >= ?p_start ))
44
45      ?indicatie a onz-zorg:WlzIndicatie ;
46                 onz-g:hasPart ?lv ;
47                 onz-g:isAbout ?client .
48      ?client a onz-g:Human .
49      ?lv a onz-zorg:Leveringsvorm ; rdfs:label ?leveringsvorm_label .
50
51      BIND(IF(?lv = onz-zorg:instelling, 1, 0) AS ?verblijf)
52      BIND(IF(?lv = onz-zorg:vpt,        1, 0) AS ?vpt)
53      BIND(IF(?lv = onz-zorg:mpt,        1, 0) AS ?mpt)
54      BIND(IF(?lv = onz-zorg:pgb,        1, 0) AS ?pgb)
55    }
56    GROUP BY ?client ?Periode
57  }
58  BIND(
59    IF((?hasVerblijf = 1) && ((?hasMPT = 1) || (?hasPGB = 1)), 1, 0)
60    AS ?hasDTV
61  )
62}
63GROUP BY ?Periode
64